[Summary view] [Print] [Text view]

   1  =head1 NAME
   2  X<regular expression> X<regex> X<regexp>
   3  
   4  perlre - Perl regular expressions
   5  
   6  =head1 DESCRIPTION
   7  
   8  This page describes the syntax of regular expressions in Perl.
   9  
  10  If you haven't used regular expressions before, a quick-start
  11  introduction is available in L<perlrequick>, and a longer tutorial
  12  introduction is available in L<perlretut>.
  13  
  14  For reference on how regular expressions are used in matching
  15  operations, plus various examples of the same, see discussions of
  16  C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
  17  Operators">.
  18  
  19  
  20  =head2 Modifiers
  21  
  22  Matching operations can have various modifiers.  Modifiers
  23  that relate to the interpretation of the regular expression inside
  24  are listed below.  Modifiers that alter the way a regular expression
  25  is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
  26  L<perlop/"Gory details of parsing quoted constructs">.
  27  
  28  =over 4
  29  
  30  =item m
  31  X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
  32  
  33  Treat string as multiple lines.  That is, change "^" and "$" from matching
  34  the start or end of the string to matching the start or end of any
  35  line anywhere within the string.
  36  
  37  =item s
  38  X</s> X<regex, single-line> X<regexp, single-line>
  39  X<regular expression, single-line>
  40  
  41  Treat string as single line.  That is, change "." to match any character
  42  whatsoever, even a newline, which normally it would not match.
  43  
  44  Used together, as /ms, they let the "." match any character whatsoever,
  45  while still allowing "^" and "$" to match, respectively, just after
  46  and just before newlines within the string.
  47  
  48  =item i
  49  X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
  50  X<regular expression, case-insensitive>
  51  
  52  Do case-insensitive pattern matching.
  53  
  54  If C<use locale> is in effect, the case map is taken from the current
  55  locale.  See L<perllocale>.
  56  
  57  =item x
  58  X</x>
  59  
  60  Extend your pattern's legibility by permitting whitespace and comments.
  61  
  62  =item p
  63  X</p> X<regex, preserve> X<regexp, preserve>
  64  
  65  Preserve the string matched such that ${^PREMATCH}, {$^MATCH}, and
  66  ${^POSTMATCH} are available for use after matching.
  67  
  68  =item g and c
  69  X</g> X</c>
  70  
  71  Global matching, and keep the Current position after failed matching.
  72  Unlike i, m, s and x, these two flags affect the way the regex is used
  73  rather than the regex itself. See
  74  L<perlretut/"Using regular expressions in Perl"> for further explanation
  75  of the g and c modifiers.
  76  
  77  =back
  78  
  79  These are usually written as "the C</x> modifier", even though the delimiter
  80  in question might not really be a slash.  Any of these
  81  modifiers may also be embedded within the regular expression itself using
  82  the C<(?...)> construct.  See below.
  83  
  84  The C</x> modifier itself needs a little more explanation.  It tells
  85  the regular expression parser to ignore whitespace that is neither
  86  backslashed nor within a character class.  You can use this to break up
  87  your regular expression into (slightly) more readable parts.  The C<#>
  88  character is also treated as a metacharacter introducing a comment,
  89  just as in ordinary Perl code.  This also means that if you want real
  90  whitespace or C<#> characters in the pattern (outside a character
  91  class, where they are unaffected by C</x>), then you'll either have to
  92  escape them (using backslashes or C<\Q...\E>) or encode them using octal
  93  or hex escapes.  Taken together, these features go a long way towards
  94  making Perl's regular expressions more readable.  Note that you have to
  95  be careful not to include the pattern delimiter in the comment--perl has
  96  no way of knowing you did not intend to close the pattern early.  See
  97  the C-comment deletion code in L<perlop>.  Also note that anything inside
  98  a C<\Q...\E> stays unaffected by C</x>.
  99  X</x>
 100  
 101  =head2 Regular Expressions
 102  
 103  =head3 Metacharacters
 104  
 105  The patterns used in Perl pattern matching evolved from the ones supplied in
 106  the Version 8 regex routines.  (The routines are derived
 107  (distantly) from Henry Spencer's freely redistributable reimplementation
 108  of the V8 routines.)  See L<Version 8 Regular Expressions> for
 109  details.
 110  
 111  In particular the following metacharacters have their standard I<egrep>-ish
 112  meanings:
 113  X<metacharacter>
 114  X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
 115  
 116  
 117      \    Quote the next metacharacter
 118      ^    Match the beginning of the line
 119      .    Match any character (except newline)
 120      $    Match the end of the line (or before newline at the end)
 121      |    Alternation
 122      ()    Grouping
 123      []    Character class
 124  
 125  By default, the "^" character is guaranteed to match only the
 126  beginning of the string, the "$" character only the end (or before the
 127  newline at the end), and Perl does certain optimizations with the
 128  assumption that the string contains only one line.  Embedded newlines
 129  will not be matched by "^" or "$".  You may, however, wish to treat a
 130  string as a multi-line buffer, such that the "^" will match after any
 131  newline within the string (except if the newline is the last character in
 132  the string), and "$" will match before any newline.  At the
 133  cost of a little more overhead, you can do this by using the /m modifier
 134  on the pattern match operator.  (Older programs did this by setting C<$*>,
 135  but this practice has been removed in perl 5.9.)
 136  X<^> X<$> X</m>
 137  
 138  To simplify multi-line substitutions, the "." character never matches a
 139  newline unless you use the C</s> modifier, which in effect tells Perl to pretend
 140  the string is a single line--even if it isn't.
 141  X<.> X</s>
 142  
 143  =head3 Quantifiers
 144  
 145  The following standard quantifiers are recognized:
 146  X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
 147  
 148      *       Match 0 or more times
 149      +       Match 1 or more times
 150      ?       Match 1 or 0 times
 151      {n}    Match exactly n times
 152      {n,}   Match at least n times
 153      {n,m}  Match at least n but not more than m times
 154  
 155  (If a curly bracket occurs in any other context, it is treated
 156  as a regular character.  In particular, the lower bound
 157  is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
 158  quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
 159  to integral values less than a preset limit defined when perl is built.
 160  This is usually 32766 on the most common platforms.  The actual limit can
 161  be seen in the error message generated by code such as this:
 162  
 163      $_ **= $_ , / {$_} / for 2 .. 42;
 164  
 165  By default, a quantified subpattern is "greedy", that is, it will match as
 166  many times as possible (given a particular starting location) while still
 167  allowing the rest of the pattern to match.  If you want it to match the
 168  minimum number of times possible, follow the quantifier with a "?".  Note
 169  that the meanings don't change, just the "greediness":
 170  X<metacharacter> X<greedy> X<greediness>
 171  X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
 172  
 173      *?     Match 0 or more times, not greedily
 174      +?     Match 1 or more times, not greedily
 175      ??     Match 0 or 1 time, not greedily
 176      {n}?   Match exactly n times, not greedily
 177      {n,}?  Match at least n times, not greedily
 178      {n,m}? Match at least n but not more than m times, not greedily
 179  
 180  By default, when a quantified subpattern does not allow the rest of the
 181  overall pattern to match, Perl will backtrack. However, this behaviour is
 182  sometimes undesirable. Thus Perl provides the "possessive" quantifier form
 183  as well.
 184  
 185      *+     Match 0 or more times and give nothing back
 186      ++     Match 1 or more times and give nothing back
 187      ?+     Match 0 or 1 time and give nothing back
 188      {n}+   Match exactly n times and give nothing back (redundant)
 189      {n,}+  Match at least n times and give nothing back
 190      {n,m}+ Match at least n but not more than m times and give nothing back
 191  
 192  For instance,
 193  
 194     'aaaa' =~ /a++a/
 195  
 196  will never match, as the C<a++> will gobble up all the C<a>'s in the
 197  string and won't leave any for the remaining part of the pattern. This
 198  feature can be extremely useful to give perl hints about where it
 199  shouldn't backtrack. For instance, the typical "match a double-quoted
 200  string" problem can be most efficiently performed when written as:
 201  
 202     /"(?:[^"\\]++|\\.)*+"/
 203  
 204  as we know that if the final quote does not match, backtracking will not
 205  help. See the independent subexpression C<< (?>...) >> for more details;
 206  possessive quantifiers are just syntactic sugar for that construct. For
 207  instance the above example could also be written as follows:
 208  
 209     /"(?>(?:(?>[^"\\]+)|\\.)*)"/
 210  
 211  =head3 Escape sequences
 212  
 213  Because patterns are processed as double quoted strings, the following
 214  also work:
 215  X<\t> X<\n> X<\r> X<\f> X<\e> X<\a> X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
 216  X<\0> X<\c> X<\N> X<\x>
 217  
 218      \t        tab                   (HT, TAB)
 219      \n        newline               (LF, NL)
 220      \r        return                (CR)
 221      \f        form feed             (FF)
 222      \a        alarm (bell)          (BEL)
 223      \e        escape (think troff)  (ESC)
 224      \033    octal char            (example: ESC)
 225      \x1B    hex char              (example: ESC)
 226      \x{263a}    long hex char         (example: Unicode SMILEY)
 227      \cK        control char          (example: VT)
 228      \N{name}    named Unicode character
 229      \l        lowercase next char (think vi)
 230      \u        uppercase next char (think vi)
 231      \L        lowercase till \E (think vi)
 232      \U        uppercase till \E (think vi)
 233      \E        end case modification (think vi)
 234      \Q        quote (disable) pattern metacharacters till \E
 235  
 236  If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
 237  and C<\U> is taken from the current locale.  See L<perllocale>.  For
 238  documentation of C<\N{name}>, see L<charnames>.
 239  
 240  You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
 241  An unescaped C<$> or C<@> interpolates the corresponding variable,
 242  while escaping will cause the literal string C<\$> to be matched.
 243  You'll need to write something like C<m/\Quser\E\@\Qhost/>.
 244  
 245  =head3 Character Classes and other Special Escapes
 246  
 247  In addition, Perl defines the following:
 248  X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\X> X<\p> X<\P> X<\C>
 249  X<\g> X<\k> X<\N> X<\K> X<\v> X<\V> X<\h> X<\H>
 250  X<word> X<whitespace> X<character class> X<backreference>
 251  
 252      \w         Match a "word" character (alphanumeric plus "_")
 253      \W         Match a non-"word" character
 254      \s         Match a whitespace character
 255      \S         Match a non-whitespace character
 256      \d         Match a digit character
 257      \D         Match a non-digit character
 258      \pP         Match P, named property.  Use \p{Prop} for longer names.
 259      \PP         Match non-P
 260      \X         Match eXtended Unicode "combining character sequence",
 261               equivalent to (?:\PM\pM*)
 262      \C         Match a single C char (octet) even under Unicode.
 263           NOTE: breaks up characters into their UTF-8 bytes,
 264           so you may end up with malformed pieces of UTF-8.
 265           Unsupported in lookbehind.
 266      \1       Backreference to a specific group.
 267           '1' may actually be any positive integer.
 268      \g1      Backreference to a specific or previous group,
 269      \g{-1}   number may be negative indicating a previous buffer and may
 270               optionally be wrapped in curly brackets for safer parsing.
 271      \g{name} Named backreference
 272      \k<name> Named backreference
 273      \K       Keep the stuff left of the \K, don't include it in $&
 274      \v       Vertical whitespace
 275      \V       Not vertical whitespace
 276      \h       Horizontal whitespace
 277      \H       Not horizontal whitespace
 278      \R       Linebreak
 279  
 280  A C<\w> matches a single alphanumeric character (an alphabetic
 281  character, or a decimal digit) or C<_>, not a whole word.  Use C<\w+>
 282  to match a string of Perl-identifier characters (which isn't the same
 283  as matching an English word).  If C<use locale> is in effect, the list
 284  of alphabetic characters generated by C<\w> is taken from the current
 285  locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
 286  C<\d>, and C<\D> within character classes, but they aren't usable
 287  as either end of a range. If any of them precedes or follows a "-",
 288  the "-" is understood literally. If Unicode is in effect, C<\s> matches
 289  also "\x{85}", "\x{2028}", and "\x{2029}". See L<perlunicode> for more
 290  details about C<\pP>, C<\PP>, C<\X> and the possibility of defining
 291  your own C<\p> and C<\P> properties, and L<perluniintro> about Unicode
 292  in general.
 293  X<\w> X<\W> X<word>
 294  
 295  C<\R> will atomically match a linebreak, including the network line-ending
 296  "\x0D\x0A".  Specifically, X<\R> is exactly equivalent to
 297  
 298    (?>\x0D\x0A?|[\x0A-\x0C\x85\x{2028}\x{2029}])
 299  
 300  B<Note:> C<\R> has no special meaning inside of a character class;
 301  use C<\v> instead (vertical whitespace).
 302  X<\R>
 303  
 304  The POSIX character class syntax
 305  X<character class>
 306  
 307      [:class:]
 308  
 309  is also available.  Note that the C<[> and C<]> brackets are I<literal>;
 310  they must always be used within a character class expression.
 311  
 312      # this is correct:
 313      $string =~ /[[:alpha:]]/;
 314  
 315      # this is not, and will generate a warning:
 316      $string =~ /[:alpha:]/;
 317  
 318  The available classes and their backslash equivalents (if available) are
 319  as follows:
 320  X<character class>
 321  X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
 322  X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
 323  
 324      alpha
 325      alnum
 326      ascii
 327      blank        [1]
 328      cntrl
 329      digit       \d
 330      graph
 331      lower
 332      print
 333      punct
 334      space       \s    [2]
 335      upper
 336      word        \w    [3]
 337      xdigit
 338  
 339  =over
 340  
 341  =item [1]
 342  
 343  A GNU extension equivalent to C<[ \t]>, "all horizontal whitespace".
 344  
 345  =item [2]
 346  
 347  Not exactly equivalent to C<\s> since the C<[[:space:]]> includes
 348  also the (very rare) "vertical tabulator", "\cK" or chr(11) in ASCII.
 349  
 350  =item [3]
 351  
 352  A Perl extension, see above.
 353  
 354  =back
 355  
 356  For example use C<[:upper:]> to match all the uppercase characters.
 357  Note that the C<[]> are part of the C<[::]> construct, not part of the
 358  whole character class.  For example:
 359  
 360      [01[:alpha:]%]
 361  
 362  matches zero, one, any alphabetic character, and the percent sign.
 363  
 364  The following equivalences to Unicode \p{} constructs and equivalent
 365  backslash character classes (if available), will hold:
 366  X<character class> X<\p> X<\p{}>
 367  
 368      [[:...:]]    \p{...}        backslash
 369  
 370      alpha       IsAlpha
 371      alnum       IsAlnum
 372      ascii       IsASCII
 373      blank
 374      cntrl       IsCntrl
 375      digit       IsDigit        \d
 376      graph       IsGraph
 377      lower       IsLower
 378      print       IsPrint
 379      punct       IsPunct
 380      space       IsSpace
 381                  IsSpacePerl    \s
 382      upper       IsUpper
 383      word        IsWord
 384      xdigit      IsXDigit
 385  
 386  For example C<[[:lower:]]> and C<\p{IsLower}> are equivalent.
 387  
 388  If the C<utf8> pragma is not used but the C<locale> pragma is, the
 389  classes correlate with the usual isalpha(3) interface (except for
 390  "word" and "blank").
 391  
 392  The other named classes are:
 393  
 394  =over 4
 395  
 396  =item cntrl
 397  X<cntrl>
 398  
 399  Any control character.  Usually characters that don't produce output as
 400  such but instead control the terminal somehow: for example newline and
 401  backspace are control characters.  All characters with ord() less than
 402  32 are usually classified as control characters (assuming ASCII,
 403  the ISO Latin character sets, and Unicode), as is the character with
 404  the ord() value of 127 (C<DEL>).
 405  
 406  =item graph
 407  X<graph>
 408  
 409  Any alphanumeric or punctuation (special) character.
 410  
 411  =item print
 412  X<print>
 413  
 414  Any alphanumeric or punctuation (special) character or the space character.
 415  
 416  =item punct
 417  X<punct>
 418  
 419  Any punctuation (special) character.
 420  
 421  =item xdigit
 422  X<xdigit>
 423  
 424  Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
 425  work just fine) it is included for completeness.
 426  
 427  =back
 428  
 429  You can negate the [::] character classes by prefixing the class name
 430  with a '^'. This is a Perl extension.  For example:
 431  X<character class, negation>
 432  
 433      POSIX         traditional  Unicode
 434  
 435      [[:^digit:]]    \D         \P{IsDigit}
 436      [[:^space:]]    \S         \P{IsSpace}
 437      [[:^word:]]        \W         \P{IsWord}
 438  
 439  Perl respects the POSIX standard in that POSIX character classes are
 440  only supported within a character class.  The POSIX character classes
 441  [.cc.] and [=cc=] are recognized but B<not> supported and trying to
 442  use them will cause an error.
 443  
 444  =head3 Assertions
 445  
 446  Perl defines the following zero-width assertions:
 447  X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
 448  X<regexp, zero-width assertion>
 449  X<regular expression, zero-width assertion>
 450  X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
 451  
 452      \b    Match a word boundary
 453      \B    Match except at a word boundary
 454      \A    Match only at beginning of string
 455      \Z    Match only at end of string, or before newline at the end
 456      \z    Match only at end of string
 457      \G    Match only at pos() (e.g. at the end-of-match position
 458          of prior m//g)
 459  
 460  A word boundary (C<\b>) is a spot between two characters
 461  that has a C<\w> on one side of it and a C<\W> on the other side
 462  of it (in either order), counting the imaginary characters off the
 463  beginning and end of the string as matching a C<\W>.  (Within
 464  character classes C<\b> represents backspace rather than a word
 465  boundary, just as it normally does in any double-quoted string.)
 466  The C<\A> and C<\Z> are just like "^" and "$", except that they
 467  won't match multiple times when the C</m> modifier is used, while
 468  "^" and "$" will match at every internal line boundary.  To match
 469  the actual end of the string and not ignore an optional trailing
 470  newline, use C<\z>.
 471  X<\b> X<\A> X<\Z> X<\z> X</m>
 472  
 473  The C<\G> assertion can be used to chain global matches (using
 474  C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
 475  It is also useful when writing C<lex>-like scanners, when you have
 476  several patterns that you want to match against consequent substrings
 477  of your string, see the previous reference.  The actual location
 478  where C<\G> will match can also be influenced by using C<pos()> as
 479  an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
 480  matches is modified somewhat, in that contents to the left of C<\G> is
 481  not counted when determining the length of the match. Thus the following
 482  will not match forever:
 483  X<\G>
 484  
 485      $str = 'ABC';
 486      pos($str) = 1;
 487      while (/.\G/g) {
 488          print $&;
 489      }
 490  
 491  It will print 'A' and then terminate, as it considers the match to
 492  be zero-width, and thus will not match at the same position twice in a
 493  row.
 494  
 495  It is worth noting that C<\G> improperly used can result in an infinite
 496  loop. Take care when using patterns that include C<\G> in an alternation.
 497  
 498  =head3 Capture buffers
 499  
 500  The bracketing construct C<( ... )> creates capture buffers. To refer
 501  to the current contents of a buffer later on, within the same pattern,
 502  use \1 for the first, \2 for the second, and so on.
 503  Outside the match use "$" instead of "\".  (The
 504  \<digit> notation works in certain circumstances outside
 505  the match.  See the warning below about \1 vs $1 for details.)
 506  Referring back to another part of the match is called a
 507  I<backreference>.
 508  X<regex, capture buffer> X<regexp, capture buffer>
 509  X<regular expression, capture buffer> X<backreference>
 510  
 511  There is no limit to the number of captured substrings that you may
 512  use.  However Perl also uses \10, \11, etc. as aliases for \010,
 513  \011, etc.  (Recall that 0 means octal, so \011 is the character at
 514  number 9 in your coded character set; which would be the 10th character,
 515  a horizontal tab under ASCII.)  Perl resolves this
 516  ambiguity by interpreting \10 as a backreference only if at least 10
 517  left parentheses have opened before it.  Likewise \11 is a
 518  backreference only if at least 11 left parentheses have opened
 519  before it.  And so on.  \1 through \9 are always interpreted as
 520  backreferences.
 521  
 522  X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
 523  In order to provide a safer and easier way to construct patterns using
 524  backreferences, Perl provides the C<\g{N}> notation (starting with perl
 525  5.10.0). The curly brackets are optional, however omitting them is less
 526  safe as the meaning of the pattern can be changed by text (such as digits)
 527  following it. When N is a positive integer the C<\g{N}> notation is
 528  exactly equivalent to using normal backreferences. When N is a negative
 529  integer then it is a relative backreference referring to the previous N'th
 530  capturing group. When the bracket form is used and N is not an integer, it
 531  is treated as a reference to a named buffer.
 532  
 533  Thus C<\g{-1}> refers to the last buffer, C<\g{-2}> refers to the
 534  buffer before that. For example:
 535  
 536          /
 537           (Y)            # buffer 1
 538           (              # buffer 2
 539              (X)         # buffer 3
 540              \g{-1}      # backref to buffer 3
 541              \g{-3}      # backref to buffer 1
 542           )
 543          /x
 544  
 545  and would match the same as C</(Y) ( (X) \3 \1 )/x>.
 546  
 547  Additionally, as of Perl 5.10.0 you may use named capture buffers and named
 548  backreferences. The notation is C<< (?<name>...) >> to declare and C<< \k<name> >>
 549  to reference. You may also use apostrophes instead of angle brackets to delimit the
 550  name; and you may use the bracketed C<< \g{name} >> backreference syntax.
 551  It's possible to refer to a named capture buffer by absolute and relative number as well.
 552  Outside the pattern, a named capture buffer is available via the C<%+> hash.
 553  When different buffers within the same pattern have the same name, C<$+{name}>
 554  and C<< \k<name> >> refer to the leftmost defined group. (Thus it's possible
 555  to do things with named capture buffers that would otherwise require C<(??{})>
 556  code to accomplish.)
 557  X<named capture buffer> X<regular expression, named capture buffer>
 558  X<%+> X<$+{name}> X<< \k<name> >>
 559  
 560  Examples:
 561  
 562      s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
 563  
 564      /(.)\1/                         # find first doubled char
 565           and print "'$1' is the first doubled character\n";
 566  
 567      /(?<char>.)\k<char>/            # ... a different way
 568           and print "'$+{char}' is the first doubled character\n";
 569  
 570      /(?'char'.)\1/                  # ... mix and match
 571           and print "'$1' is the first doubled character\n";
 572  
 573      if (/Time: (..):(..):(..)/) {   # parse out values
 574      $hours = $1;
 575      $minutes = $2;
 576      $seconds = $3;
 577      }
 578  
 579  Several special variables also refer back to portions of the previous
 580  match.  C<$+> returns whatever the last bracket match matched.
 581  C<$&> returns the entire matched string.  (At one point C<$0> did
 582  also, but now it returns the name of the program.)  C<$`> returns
 583  everything before the matched string.  C<$'> returns everything
 584  after the matched string. And C<$^N> contains whatever was matched by
 585  the most-recently closed group (submatch). C<$^N> can be used in
 586  extended patterns (see below), for example to assign a submatch to a
 587  variable.
 588  X<$+> X<$^N> X<$&> X<$`> X<$'>
 589  
 590  The numbered match variables ($1, $2, $3, etc.) and the related punctuation
 591  set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
 592  until the end of the enclosing block or until the next successful
 593  match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
 594  X<$+> X<$^N> X<$&> X<$`> X<$'>
 595  X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
 596  
 597  
 598  B<NOTE>: Failed matches in Perl do not reset the match variables,
 599  which makes it easier to write code that tests for a series of more
 600  specific cases and remembers the best match.
 601  
 602  B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
 603  C<$'> anywhere in the program, it has to provide them for every
 604  pattern match.  This may substantially slow your program.  Perl
 605  uses the same mechanism to produce $1, $2, etc, so you also pay a
 606  price for each pattern that contains capturing parentheses.  (To
 607  avoid this cost while retaining the grouping behaviour, use the
 608  extended regular expression C<(?: ... )> instead.)  But if you never
 609  use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
 610  parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
 611  if you can, but if you can't (and some algorithms really appreciate
 612  them), once you've used them once, use them at will, because you've
 613  already paid the price.  As of 5.005, C<$&> is not so costly as the
 614  other two.
 615  X<$&> X<$`> X<$'>
 616  
 617  As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
 618  C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
 619  and C<$'>, B<except> that they are only guaranteed to be defined after a
 620  successful match that was executed with the C</p> (preserve) modifier.
 621  The use of these variables incurs no global performance penalty, unlike
 622  their punctuation char equivalents, however at the trade-off that you
 623  have to tell perl when you want to use them.
 624  X</p> X<p modifier>
 625  
 626  Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
 627  C<\w>, C<\n>.  Unlike some other regular expression languages, there
 628  are no backslashed symbols that aren't alphanumeric.  So anything
 629  that looks like \\, \(, \), \<, \>, \{, or \} is always
 630  interpreted as a literal character, not a metacharacter.  This was
 631  once used in a common idiom to disable or quote the special meanings
 632  of regular expression metacharacters in a string that you want to
 633  use for a pattern. Simply quote all non-"word" characters:
 634  
 635      $pattern =~ s/(\W)/\\$1/g;
 636  
 637  (If C<use locale> is set, then this depends on the current locale.)
 638  Today it is more common to use the quotemeta() function or the C<\Q>
 639  metaquoting escape sequence to disable all metacharacters' special
 640  meanings like this:
 641  
 642      /$unquoted\Q$quoted\E$unquoted/
 643  
 644  Beware that if you put literal backslashes (those not inside
 645  interpolated variables) between C<\Q> and C<\E>, double-quotish
 646  backslash interpolation may lead to confusing results.  If you
 647  I<need> to use literal backslashes within C<\Q...\E>,
 648  consult L<perlop/"Gory details of parsing quoted constructs">.
 649  
 650  =head2 Extended Patterns
 651  
 652  Perl also defines a consistent extension syntax for features not
 653  found in standard tools like B<awk> and B<lex>.  The syntax is a
 654  pair of parentheses with a question mark as the first thing within
 655  the parentheses.  The character after the question mark indicates
 656  the extension.
 657  
 658  The stability of these extensions varies widely.  Some have been
 659  part of the core language for many years.  Others are experimental
 660  and may change without warning or be completely removed.  Check
 661  the documentation on an individual feature to verify its current
 662  status.
 663  
 664  A question mark was chosen for this and for the minimal-matching
 665  construct because 1) question marks are rare in older regular
 666  expressions, and 2) whenever you see one, you should stop and
 667  "question" exactly what is going on.  That's psychology...
 668  
 669  =over 10
 670  
 671  =item C<(?#text)>
 672  X<(?#)>
 673  
 674  A comment.  The text is ignored.  If the C</x> modifier enables
 675  whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
 676  the comment as soon as it sees a C<)>, so there is no way to put a literal
 677  C<)> in the comment.
 678  
 679  =item C<(?pimsx-imsx)>
 680  X<(?)>
 681  
 682  One or more embedded pattern-match modifiers, to be turned on (or
 683  turned off, if preceded by C<->) for the remainder of the pattern or
 684  the remainder of the enclosing pattern group (if any). This is
 685  particularly useful for dynamic patterns, such as those read in from a
 686  configuration file, taken from an argument, or specified in a table
 687  somewhere.  Consider the case where some patterns want to be case
 688  sensitive and some do not:  The case insensitive ones merely need to
 689  include C<(?i)> at the front of the pattern.  For example:
 690  
 691      $pattern = "foobar";
 692      if ( /$pattern/i ) { }
 693  
 694      # more flexible:
 695  
 696      $pattern = "(?i)foobar";
 697      if ( /$pattern/ ) { }
 698  
 699  These modifiers are restored at the end of the enclosing group. For example,
 700  
 701      ( (?i) blah ) \s+ \1
 702  
 703  will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
 704  repetition of the previous word, assuming the C</x> modifier, and no C</i>
 705  modifier outside this group.
 706  
 707  Note that the C<p> modifier is special in that it can only be enabled,
 708  not disabled, and that its presence anywhere in a pattern has a global
 709  effect. Thus C<(?-p)> and C<(?-p:...)> are meaningless and will warn
 710  when executed under C<use warnings>.
 711  
 712  =item C<(?:pattern)>
 713  X<(?:)>
 714  
 715  =item C<(?imsx-imsx:pattern)>
 716  
 717  This is for clustering, not capturing; it groups subexpressions like
 718  "()", but doesn't make backreferences as "()" does.  So
 719  
 720      @fields = split(/\b(?:a|b|c)\b/)
 721  
 722  is like
 723  
 724      @fields = split(/\b(a|b|c)\b/)
 725  
 726  but doesn't spit out extra fields.  It's also cheaper not to capture
 727  characters if you don't need to.
 728  
 729  Any letters between C<?> and C<:> act as flags modifiers as with
 730  C<(?imsx-imsx)>.  For example,
 731  
 732      /(?s-i:more.*than).*million/i
 733  
 734  is equivalent to the more verbose
 735  
 736      /(?:(?s-i)more.*than).*million/i
 737  
 738  =item C<(?|pattern)>
 739  X<(?|)> X<Branch reset>
 740  
 741  This is the "branch reset" pattern, which has the special property
 742  that the capture buffers are numbered from the same starting point
 743  in each alternation branch. It is available starting from perl 5.10.0.
 744  
 745  Capture buffers are numbered from left to right, but inside this
 746  construct the numbering is restarted for each branch.
 747  
 748  The numbering within each branch will be as normal, and any buffers
 749  following this construct will be numbered as though the construct
 750  contained only one branch, that being the one with the most capture
 751  buffers in it.
 752  
 753  This construct will be useful when you want to capture one of a
 754  number of alternative matches.
 755  
 756  Consider the following pattern.  The numbers underneath show in
 757  which buffer the captured content will be stored.
 758  
 759  
 760      # before  ---------------branch-reset----------- after        
 761      / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
 762      # 1            2         2  3        2     3     4  
 763  
 764  Note: as of Perl 5.10.0, branch resets interfere with the contents of
 765  the C<%+> hash, that holds named captures. Consider using C<%-> instead.
 766  
 767  =item Look-Around Assertions
 768  X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
 769  
 770  Look-around assertions are zero width patterns which match a specific
 771  pattern without including it in C<$&>. Positive assertions match when
 772  their subpattern matches, negative assertions match when their subpattern
 773  fails. Look-behind matches text up to the current match position,
 774  look-ahead matches text following the current match position.
 775  
 776  =over 4
 777  
 778  =item C<(?=pattern)>
 779  X<(?=)> X<look-ahead, positive> X<lookahead, positive>
 780  
 781  A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
 782  matches a word followed by a tab, without including the tab in C<$&>.
 783  
 784  =item C<(?!pattern)>
 785  X<(?!)> X<look-ahead, negative> X<lookahead, negative>
 786  
 787  A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
 788  matches any occurrence of "foo" that isn't followed by "bar".  Note
 789  however that look-ahead and look-behind are NOT the same thing.  You cannot
 790  use this for look-behind.
 791  
 792  If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
 793  will not do what you want.  That's because the C<(?!foo)> is just saying that
 794  the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
 795  match.  You would have to do something like C</(?!foo)...bar/> for that.   We
 796  say "like" because there's the case of your "bar" not having three characters
 797  before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
 798  Sometimes it's still easier just to say:
 799  
 800      if (/bar/ && $` !~ /foo$/)
 801  
 802  For look-behind see below.
 803  
 804  =item C<(?<=pattern)> C<\K>
 805  X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
 806  
 807  A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
 808  matches a word that follows a tab, without including the tab in C<$&>.
 809  Works only for fixed-width look-behind.
 810  
 811  There is a special form of this construct, called C<\K>, which causes the
 812  regex engine to "keep" everything it had matched prior to the C<\K> and
 813  not include it in C<$&>. This effectively provides variable length
 814  look-behind. The use of C<\K> inside of another look-around assertion
 815  is allowed, but the behaviour is currently not well defined.
 816  
 817  For various reasons C<\K> may be significantly more efficient than the
 818  equivalent C<< (?<=...) >> construct, and it is especially useful in
 819  situations where you want to efficiently remove something following
 820  something else in a string. For instance
 821  
 822    s/(foo)bar/$1/g;
 823  
 824  can be rewritten as the much more efficient
 825  
 826    s/foo\Kbar//g;
 827  
 828  =item C<(?<!pattern)>
 829  X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
 830  
 831  A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
 832  matches any occurrence of "foo" that does not follow "bar".  Works
 833  only for fixed-width look-behind.
 834  
 835  =back
 836  
 837  =item C<(?'NAME'pattern)>
 838  
 839  =item C<< (?<NAME>pattern) >>
 840  X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
 841  
 842  A named capture buffer. Identical in every respect to normal capturing
 843  parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
 844  used after a successful match to refer to a named buffer. See C<perlvar>
 845  for more details on the C<%+> and C<%-> hashes.
 846  
 847  If multiple distinct capture buffers have the same name then the
 848  $+{NAME} will refer to the leftmost defined buffer in the match.
 849  
 850  The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
 851  
 852  B<NOTE:> While the notation of this construct is the same as the similar
 853  function in .NET regexes, the behavior is not. In Perl the buffers are
 854  numbered sequentially regardless of being named or not. Thus in the
 855  pattern
 856  
 857    /(x)(?<foo>y)(z)/
 858  
 859  $+{foo} will be the same as $2, and $3 will contain 'z' instead of
 860  the opposite which is what a .NET regex hacker might expect.
 861  
 862  Currently NAME is restricted to simple identifiers only.
 863  In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
 864  its Unicode extension (see L<utf8>),
 865  though it isn't extended by the locale (see L<perllocale>).
 866  
 867  B<NOTE:> In order to make things easier for programmers with experience
 868  with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
 869  may be used instead of C<< (?<NAME>pattern) >>; however this form does not
 870  support the use of single quotes as a delimiter for the name.
 871  
 872  =item C<< \k<NAME> >>
 873  
 874  =item C<< \k'NAME' >>
 875  
 876  Named backreference. Similar to numeric backreferences, except that
 877  the group is designated by name and not number. If multiple groups
 878  have the same name then it refers to the leftmost defined group in
 879  the current match.
 880  
 881  It is an error to refer to a name not defined by a C<< (?<NAME>) >>
 882  earlier in the pattern.
 883  
 884  Both forms are equivalent.
 885  
 886  B<NOTE:> In order to make things easier for programmers with experience
 887  with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
 888  may be used instead of C<< \k<NAME> >>.
 889  
 890  =item C<(?{ code })>
 891  X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
 892  
 893  B<WARNING>: This extended regular expression feature is considered
 894  experimental, and may be changed without notice. Code executed that
 895  has side effects may not perform identically from version to version
 896  due to the effect of future optimisations in the regex engine.
 897  
 898  This zero-width assertion evaluates any embedded Perl code.  It
 899  always succeeds, and its C<code> is not interpolated.  Currently,
 900  the rules to determine where the C<code> ends are somewhat convoluted.
 901  
 902  This feature can be used together with the special variable C<$^N> to
 903  capture the results of submatches in variables without having to keep
 904  track of the number of nested parentheses. For example:
 905  
 906    $_ = "The brown fox jumps over the lazy dog";
 907    /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
 908    print "color = $color, animal = $animal\n";
 909  
 910  Inside the C<(?{...})> block, C<$_> refers to the string the regular
 911  expression is matching against. You can also use C<pos()> to know what is
 912  the current position of matching within this string.
 913  
 914  The C<code> is properly scoped in the following sense: If the assertion
 915  is backtracked (compare L<"Backtracking">), all changes introduced after
 916  C<local>ization are undone, so that
 917  
 918    $_ = 'a' x 8;
 919    m<
 920       (?{ $cnt = 0 })            # Initialize $cnt.
 921       (
 922         a
 923         (?{
 924             local $cnt = $cnt + 1;    # Update $cnt, backtracking-safe.
 925         })
 926       )*
 927       aaaa
 928       (?{ $res = $cnt })            # On success copy to non-localized
 929                      # location.
 930     >x;
 931  
 932  will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
 933  introduced value, because the scopes that restrict C<local> operators
 934  are unwound.
 935  
 936  This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
 937  switch.  If I<not> used in this way, the result of evaluation of
 938  C<code> is put into the special variable C<$^R>.  This happens
 939  immediately, so C<$^R> can be used from other C<(?{ code })> assertions
 940  inside the same regular expression.
 941  
 942  The assignment to C<$^R> above is properly localized, so the old
 943  value of C<$^R> is restored if the assertion is backtracked; compare
 944  L<"Backtracking">.
 945  
 946  Due to an unfortunate implementation issue, the Perl code contained in these
 947  blocks is treated as a compile time closure that can have seemingly bizarre
 948  consequences when used with lexically scoped variables inside of subroutines
 949  or loops.  There are various workarounds for this, including simply using
 950  global variables instead.  If you are using this construct and strange results
 951  occur then check for the use of lexically scoped variables.
 952  
 953  For reasons of security, this construct is forbidden if the regular
 954  expression involves run-time interpolation of variables, unless the
 955  perilous C<use re 'eval'> pragma has been used (see L<re>), or the
 956  variables contain results of C<qr//> operator (see
 957  L<perlop/"qr/STRING/imosx">).
 958  
 959  This restriction is due to the wide-spread and remarkably convenient
 960  custom of using run-time determined strings as patterns.  For example:
 961  
 962      $re = <>;
 963      chomp $re;
 964      $string =~ /$re/;
 965  
 966  Before Perl knew how to execute interpolated code within a pattern,
 967  this operation was completely safe from a security point of view,
 968  although it could raise an exception from an illegal pattern.  If
 969  you turn on the C<use re 'eval'>, though, it is no longer secure,
 970  so you should only do so if you are also using taint checking.
 971  Better yet, use the carefully constrained evaluation within a Safe
 972  compartment.  See L<perlsec> for details about both these mechanisms.
 973  
 974  Because Perl's regex engine is currently not re-entrant, interpolated
 975  code may not invoke the regex engine either directly with C<m//> or C<s///>),
 976  or indirectly with functions such as C<split>.
 977  
 978  =item C<(??{ code })>
 979  X<(??{})>
 980  X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
 981  
 982  B<WARNING>: This extended regular expression feature is considered
 983  experimental, and may be changed without notice. Code executed that
 984  has side effects may not perform identically from version to version
 985  due to the effect of future optimisations in the regex engine.
 986  
 987  This is a "postponed" regular subexpression.  The C<code> is evaluated
 988  at run time, at the moment this subexpression may match.  The result
 989  of evaluation is considered as a regular expression and matched as
 990  if it were inserted instead of this construct.  Note that this means
 991  that the contents of capture buffers defined inside an eval'ed pattern
 992  are not available outside of the pattern, and vice versa, there is no
 993  way for the inner pattern to refer to a capture buffer defined outside.
 994  Thus,
 995  
 996      ('a' x 100)=~/(??{'(.)' x 100})/
 997  
 998  B<will> match, it will B<not> set $1.
 999  
1000  The C<code> is not interpolated.  As before, the rules to determine
1001  where the C<code> ends are currently somewhat convoluted.
1002  
1003  The following pattern matches a parenthesized group:
1004  
1005    $re = qr{
1006           \(
1007           (?:
1008          (?> [^()]+ )    # Non-parens without backtracking
1009            |
1010          (??{ $re })    # Group with matching parens
1011           )*
1012           \)
1013        }x;
1014  
1015  See also C<(?PARNO)> for a different, more efficient way to accomplish
1016  the same task.
1017  
1018  Because perl's regex engine is not currently re-entrant, delayed
1019  code may not invoke the regex engine either directly with C<m//> or C<s///>),
1020  or indirectly with functions such as C<split>.
1021  
1022  Recursing deeper than 50 times without consuming any input string will
1023  result in a fatal error.  The maximum depth is compiled into perl, so
1024  changing it requires a custom build.
1025  
1026  =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1027  X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1028  X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1029  X<regex, relative recursion>
1030  
1031  Similar to C<(??{ code })> except it does not involve compiling any code,
1032  instead it treats the contents of a capture buffer as an independent
1033  pattern that must match at the current position.  Capture buffers
1034  contained by the pattern will have the value as determined by the
1035  outermost recursion.
1036  
1037  PARNO is a sequence of digits (not starting with 0) whose value reflects
1038  the paren-number of the capture buffer to recurse to. C<(?R)> recurses to
1039  the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1040  C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1041  to be relative, with negative numbers indicating preceding capture buffers
1042  and positive ones following. Thus C<(?-1)> refers to the most recently
1043  declared buffer, and C<(?+1)> indicates the next buffer to be declared.
1044  Note that the counting for relative recursion differs from that of
1045  relative backreferences, in that with recursion unclosed buffers B<are>
1046  included.
1047  
1048  The following pattern matches a function foo() which may contain
1049  balanced parentheses as the argument.
1050  
1051    $re = qr{ (                    # paren group 1 (full function)
1052                foo
1053                (                  # paren group 2 (parens)
1054                  \(
1055                    (              # paren group 3 (contents of parens)
1056                    (?:
1057                     (?> [^()]+ )  # Non-parens without backtracking
1058                    |
1059                     (?2)          # Recurse to start of paren group 2
1060                    )*
1061                    )
1062                  \)
1063                )
1064              )
1065            }x;
1066  
1067  If the pattern was used as follows
1068  
1069      'foo(bar(baz)+baz(bop))'=~/$re/
1070          and print "\$1 = $1\n",
1071                    "\$2 = $2\n",
1072                    "\$3 = $3\n";
1073  
1074  the output produced should be the following:
1075  
1076      $1 = foo(bar(baz)+baz(bop))
1077      $2 = (bar(baz)+baz(bop))
1078      $3 = bar(baz)+baz(bop)
1079  
1080  If there is no corresponding capture buffer defined, then it is a
1081  fatal error.  Recursing deeper than 50 times without consuming any input
1082  string will also result in a fatal error.  The maximum depth is compiled
1083  into perl, so changing it requires a custom build.
1084  
1085  The following shows how using negative indexing can make it
1086  easier to embed recursive patterns inside of a C<qr//> construct
1087  for later use:
1088  
1089      my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1090      if (/foo $parens \s+ + \s+ bar $parens/x) {
1091         # do something here...
1092      }
1093  
1094  B<Note> that this pattern does not behave the same way as the equivalent
1095  PCRE or Python construct of the same form. In Perl you can backtrack into
1096  a recursed group, in PCRE and Python the recursed into group is treated
1097  as atomic. Also, modifiers are resolved at compile time, so constructs
1098  like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1099  be processed.
1100  
1101  =item C<(?&NAME)>
1102  X<(?&NAME)>
1103  
1104  Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1105  parenthesis to recurse to is determined by name. If multiple parentheses have
1106  the same name, then it recurses to the leftmost.
1107  
1108  It is an error to refer to a name that is not declared somewhere in the
1109  pattern.
1110  
1111  B<NOTE:> In order to make things easier for programmers with experience
1112  with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1113  may be used instead of C<< (?&NAME) >>.
1114  
1115  =item C<(?(condition)yes-pattern|no-pattern)>
1116  X<(?()>
1117  
1118  =item C<(?(condition)yes-pattern)>
1119  
1120  Conditional expression.  C<(condition)> should be either an integer in
1121  parentheses (which is valid if the corresponding pair of parentheses
1122  matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1123  name in angle brackets or single quotes (which is valid if a buffer
1124  with the given name matched), or the special symbol (R) (true when
1125  evaluated inside of recursion or eval). Additionally the R may be
1126  followed by a number, (which will be true when evaluated when recursing
1127  inside of the appropriate group), or by C<&NAME>, in which case it will
1128  be true only when evaluated during recursion in the named group.
1129  
1130  Here's a summary of the possible predicates:
1131  
1132  =over 4
1133  
1134  =item (1) (2) ...
1135  
1136  Checks if the numbered capturing buffer has matched something.
1137  
1138  =item (<NAME>) ('NAME')
1139  
1140  Checks if a buffer with the given name has matched something.
1141  
1142  =item (?{ CODE })
1143  
1144  Treats the code block as the condition.
1145  
1146  =item (R)
1147  
1148  Checks if the expression has been evaluated inside of recursion.
1149  
1150  =item (R1) (R2) ...
1151  
1152  Checks if the expression has been evaluated while executing directly
1153  inside of the n-th capture group. This check is the regex equivalent of
1154  
1155    if ((caller(0))[3] eq 'subname') { ... }
1156  
1157  In other words, it does not check the full recursion stack.
1158  
1159  =item (R&NAME)
1160  
1161  Similar to C<(R1)>, this predicate checks to see if we're executing
1162  directly inside of the leftmost group with a given name (this is the same
1163  logic used by C<(?&NAME)> to disambiguate). It does not check the full
1164  stack, but only the name of the innermost active recursion.
1165  
1166  =item (DEFINE)
1167  
1168  In this case, the yes-pattern is never directly executed, and no
1169  no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1170  See below for details.
1171  
1172  =back
1173  
1174  For example:
1175  
1176      m{ ( \( )?
1177         [^()]+
1178         (?(1) \) )
1179       }x
1180  
1181  matches a chunk of non-parentheses, possibly included in parentheses
1182  themselves.
1183  
1184  A special form is the C<(DEFINE)> predicate, which never executes directly
1185  its yes-pattern, and does not allow a no-pattern. This allows to define
1186  subpatterns which will be executed only by using the recursion mechanism.
1187  This way, you can define a set of regular expression rules that can be
1188  bundled into any pattern you choose.
1189  
1190  It is recommended that for this usage you put the DEFINE block at the
1191  end of the pattern, and that you name any subpatterns defined within it.
1192  
1193  Also, it's worth noting that patterns defined this way probably will
1194  not be as efficient, as the optimiser is not very clever about
1195  handling them.
1196  
1197  An example of how this might be used is as follows:
1198  
1199    /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1200     (?(DEFINE)
1201       (?<NAME_PAT>....)
1202       (?<ADRESS_PAT>....)
1203     )/x
1204  
1205  Note that capture buffers matched inside of recursion are not accessible
1206  after the recursion returns, so the extra layer of capturing buffers is
1207  necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1208  C<$+{NAME}> would be.
1209  
1210  =item C<< (?>pattern) >>
1211  X<backtrack> X<backtracking> X<atomic> X<possessive>
1212  
1213  An "independent" subexpression, one which matches the substring
1214  that a I<standalone> C<pattern> would match if anchored at the given
1215  position, and it matches I<nothing other than this substring>.  This
1216  construct is useful for optimizations of what would otherwise be
1217  "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1218  It may also be useful in places where the "grab all you can, and do not
1219  give anything back" semantic is desirable.
1220  
1221  For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1222  (anchored at the beginning of string, as above) will match I<all>
1223  characters C<a> at the beginning of string, leaving no C<a> for
1224  C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1225  since the match of the subgroup C<a*> is influenced by the following
1226  group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1227  C<a*ab> will match fewer characters than a standalone C<a*>, since
1228  this makes the tail match.
1229  
1230  An effect similar to C<< (?>pattern) >> may be achieved by writing
1231  C<(?=(pattern))\1>.  This matches the same substring as a standalone
1232  C<a+>, and the following C<\1> eats the matched string; it therefore
1233  makes a zero-length assertion into an analogue of C<< (?>...) >>.
1234  (The difference between these two constructs is that the second one
1235  uses a capturing group, thus shifting ordinals of backreferences
1236  in the rest of a regular expression.)
1237  
1238  Consider this pattern:
1239  
1240      m{ \(
1241            (
1242              [^()]+        # x+
1243            |
1244              \( [^()]* \)
1245            )+
1246         \)
1247       }x
1248  
1249  That will efficiently match a nonempty group with matching parentheses
1250  two levels deep or less.  However, if there is no such group, it
1251  will take virtually forever on a long string.  That's because there
1252  are so many different ways to split a long string into several
1253  substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1254  to a subpattern of the above pattern.  Consider how the pattern
1255  above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1256  seconds, but that each extra letter doubles this time.  This
1257  exponential performance will make it appear that your program has
1258  hung.  However, a tiny change to this pattern
1259  
1260      m{ \(
1261            (
1262              (?> [^()]+ )    # change x+ above to (?> x+ )
1263            |
1264              \( [^()]* \)
1265            )+
1266         \)
1267       }x
1268  
1269  which uses C<< (?>...) >> matches exactly when the one above does (verifying
1270  this yourself would be a productive exercise), but finishes in a fourth
1271  the time when used on a similar string with 1000000 C<a>s.  Be aware,
1272  however, that this pattern currently triggers a warning message under
1273  the C<use warnings> pragma or B<-w> switch saying it
1274  C<"matches null string many times in regex">.
1275  
1276  On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1277  effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1278  This was only 4 times slower on a string with 1000000 C<a>s.
1279  
1280  The "grab all you can, and do not give anything back" semantic is desirable
1281  in many situations where on the first sight a simple C<()*> looks like
1282  the correct solution.  Suppose we parse text with comments being delimited
1283  by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1284  its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1285  the comment delimiter, because it may "give up" some whitespace if
1286  the remainder of the pattern can be made to match that way.  The correct
1287  answer is either one of these:
1288  
1289      (?>#[ \t]*)
1290      #[ \t]*(?![ \t])
1291  
1292  For example, to grab non-empty comments into $1, one should use either
1293  one of these:
1294  
1295      / (?> \# [ \t]* ) (        .+ ) /x;
1296      /     \# [ \t]*   ( [^ \t] .* ) /x;
1297  
1298  Which one you pick depends on which of these expressions better reflects
1299  the above specification of comments.
1300  
1301  In some literature this construct is called "atomic matching" or
1302  "possessive matching".
1303  
1304  Possessive quantifiers are equivalent to putting the item they are applied
1305  to inside of one of these constructs. The following equivalences apply:
1306  
1307      Quantifier Form     Bracketing Form
1308      ---------------     ---------------
1309      PAT*+               (?>PAT*)
1310      PAT++               (?>PAT+)
1311      PAT?+               (?>PAT?)
1312      PAT{min,max}+       (?>PAT{min,max})
1313  
1314  =back
1315  
1316  =head2 Special Backtracking Control Verbs
1317  
1318  B<WARNING:> These patterns are experimental and subject to change or
1319  removal in a future version of Perl. Their usage in production code should
1320  be noted to avoid problems during upgrades.
1321  
1322  These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1323  otherwise stated the ARG argument is optional; in some cases, it is
1324  forbidden.
1325  
1326  Any pattern containing a special backtracking verb that allows an argument
1327  has the special behaviour that when executed it sets the current packages'
1328  C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1329  rules apply:
1330  
1331  On failure, the C<$REGERROR> variable will be set to the ARG value of the
1332  verb pattern, if the verb was involved in the failure of the match. If the
1333  ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1334  name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1335  none. Also, the C<$REGMARK> variable will be set to FALSE.
1336  
1337  On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1338  the C<$REGMARK> variable will be set to the name of the last
1339  C<(*MARK:NAME)> pattern executed.  See the explanation for the
1340  C<(*MARK:NAME)> verb below for more details.
1341  
1342  B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1343  and most other regex related variables. They are not local to a scope, nor
1344  readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1345  Use C<local> to localize changes to them to a specific scope if necessary.
1346  
1347  If a pattern does not contain a special backtracking verb that allows an
1348  argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1349  
1350  =over 4
1351  
1352  =item Verbs that take an argument
1353  
1354  =over 4
1355  
1356  =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1357  X<(*PRUNE)> X<(*PRUNE:NAME)>
1358  
1359  This zero-width pattern prunes the backtracking tree at the current point
1360  when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1361  where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1362  A may backtrack as necessary to match. Once it is reached, matching
1363  continues in B, which may also backtrack as necessary; however, should B
1364  not match, then no further backtracking will take place, and the pattern
1365  will fail outright at the current starting position.
1366  
1367  The following example counts all the possible matching strings in a
1368  pattern (without actually matching any of them).
1369  
1370      'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1371      print "Count=$count\n";
1372  
1373  which produces:
1374  
1375      aaab
1376      aaa
1377      aa
1378      a
1379      aab
1380      aa
1381      a
1382      ab
1383      a
1384      Count=9
1385  
1386  If we add a C<(*PRUNE)> before the count like the following
1387  
1388      'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1389      print "Count=$count\n";
1390  
1391  we prevent backtracking and find the count of the longest matching
1392  at each matching starting point like so:
1393  
1394      aaab
1395      aab
1396      ab
1397      Count=3
1398  
1399  Any number of C<(*PRUNE)> assertions may be used in a pattern.
1400  
1401  See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1402  control backtracking. In some cases, the use of C<(*PRUNE)> can be
1403  replaced with a C<< (?>pattern) >> with no functional difference; however,
1404  C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1405  C<< (?>pattern) >> alone.
1406  
1407  
1408  =item C<(*SKIP)> C<(*SKIP:NAME)>
1409  X<(*SKIP)>
1410  
1411  This zero-width pattern is similar to C<(*PRUNE)>, except that on
1412  failure it also signifies that whatever text that was matched leading up
1413  to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1414  of this pattern. This effectively means that the regex engine "skips" forward
1415  to this position on failure and tries to match again, (assuming that
1416  there is sufficient room to match).
1417  
1418  The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1419  C<(*MARK:NAME)> was encountered while matching, then it is that position
1420  which is used as the "skip point". If no C<(*MARK)> of that name was
1421  encountered, then the C<(*SKIP)> operator has no effect. When used
1422  without a name the "skip point" is where the match point was when
1423  executing the (*SKIP) pattern.
1424  
1425  Compare the following to the examples in C<(*PRUNE)>, note the string
1426  is twice as long:
1427  
1428      'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1429      print "Count=$count\n";
1430  
1431  outputs
1432  
1433      aaab
1434      aaab
1435      Count=2
1436  
1437  Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1438  executed, the next starting point will be where the cursor was when the
1439  C<(*SKIP)> was executed.
1440  
1441  =item C<(*MARK:NAME)> C<(*:NAME)>
1442  X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1443  
1444  This zero-width pattern can be used to mark the point reached in a string
1445  when a certain part of the pattern has been successfully matched. This
1446  mark may be given a name. A later C<(*SKIP)> pattern will then skip
1447  forward to that point if backtracked into on failure. Any number of
1448  C<(*MARK)> patterns are allowed, and the NAME portion is optional and may
1449  be duplicated.
1450  
1451  In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1452  can be used to "label" a pattern branch, so that after matching, the
1453  program can determine which branches of the pattern were involved in the
1454  match.
1455  
1456  When a match is successful, the C<$REGMARK> variable will be set to the
1457  name of the most recently executed C<(*MARK:NAME)> that was involved
1458  in the match.
1459  
1460  This can be used to determine which branch of a pattern was matched
1461  without using a separate capture buffer for each branch, which in turn
1462  can result in a performance improvement, as perl cannot optimize
1463  C</(?:(x)|(y)|(z))/> as efficiently as something like
1464  C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1465  
1466  When a match has failed, and unless another verb has been involved in
1467  failing the match and has provided its own name to use, the C<$REGERROR>
1468  variable will be set to the name of the most recently executed
1469  C<(*MARK:NAME)>.
1470  
1471  See C<(*SKIP)> for more details.
1472  
1473  As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1474  
1475  =item C<(*THEN)> C<(*THEN:NAME)>
1476  
1477  This is similar to the "cut group" operator C<::> from Perl 6. Like
1478  C<(*PRUNE)>, this verb always matches, and when backtracked into on
1479  failure, it causes the regex engine to try the next alternation in the
1480  innermost enclosing group (capturing or otherwise).
1481  
1482  Its name comes from the observation that this operation combined with the
1483  alternation operator (C<|>) can be used to create what is essentially a
1484  pattern-based if/then/else block:
1485  
1486    ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1487  
1488  Note that if this operator is used and NOT inside of an alternation then
1489  it acts exactly like the C<(*PRUNE)> operator.
1490  
1491    / A (*PRUNE) B /
1492  
1493  is the same as
1494  
1495    / A (*THEN) B /
1496  
1497  but
1498  
1499    / ( A (*THEN) B | C (*THEN) D ) /
1500  
1501  is not the same as
1502  
1503    / ( A (*PRUNE) B | C (*PRUNE) D ) /
1504  
1505  as after matching the A but failing on the B the C<(*THEN)> verb will
1506  backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1507  
1508  =item C<(*COMMIT)>
1509  X<(*COMMIT)>
1510  
1511  This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1512  zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1513  into on failure it causes the match to fail outright. No further attempts
1514  to find a valid match by advancing the start pointer will occur again.
1515  For example,
1516  
1517      'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1518      print "Count=$count\n";
1519  
1520  outputs
1521  
1522      aaab
1523      Count=1
1524  
1525  In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1526  does not match, the regex engine will not try any further matching on the
1527  rest of the string.
1528  
1529  =back
1530  
1531  =item Verbs without an argument
1532  
1533  =over 4
1534  
1535  =item C<(*FAIL)> C<(*F)>
1536  X<(*FAIL)> X<(*F)>
1537  
1538  This pattern matches nothing and always fails. It can be used to force the
1539  engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1540  fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1541  
1542  It is probably useful only when combined with C<(?{})> or C<(??{})>.
1543  
1544  =item C<(*ACCEPT)>
1545  X<(*ACCEPT)>
1546  
1547  B<WARNING:> This feature is highly experimental. It is not recommended
1548  for production code.
1549  
1550  This pattern matches nothing and causes the end of successful matching at
1551  the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1552  whether there is actually more to match in the string. When inside of a
1553  nested pattern, such as recursion, or in a subpattern dynamically generated
1554  via C<(??{})>, only the innermost pattern is ended immediately.
1555  
1556  If the C<(*ACCEPT)> is inside of capturing buffers then the buffers are
1557  marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1558  For instance:
1559  
1560    'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1561  
1562  will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1563  be set. If another branch in the inner parentheses were matched, such as in the
1564  string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1565  
1566  =back
1567  
1568  =back
1569  
1570  =head2 Backtracking
1571  X<backtrack> X<backtracking>
1572  
1573  NOTE: This section presents an abstract approximation of regular
1574  expression behavior.  For a more rigorous (and complicated) view of
1575  the rules involved in selecting a match among possible alternatives,
1576  see L<Combining RE Pieces>.
1577  
1578  A fundamental feature of regular expression matching involves the
1579  notion called I<backtracking>, which is currently used (when needed)
1580  by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1581  C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1582  internally, but the general principle outlined here is valid.
1583  
1584  For a regular expression to match, the I<entire> regular expression must
1585  match, not just part of it.  So if the beginning of a pattern containing a
1586  quantifier succeeds in a way that causes later parts in the pattern to
1587  fail, the matching engine backs up and recalculates the beginning
1588  part--that's why it's called backtracking.
1589  
1590  Here is an example of backtracking:  Let's say you want to find the
1591  word following "foo" in the string "Food is on the foo table.":
1592  
1593      $_ = "Food is on the foo table.";
1594      if ( /\b(foo)\s+(\w+)/i ) {
1595      print "$2 follows $1.\n";
1596      }
1597  
1598  When the match runs, the first part of the regular expression (C<\b(foo)>)
1599  finds a possible match right at the beginning of the string, and loads up
1600  $1 with "Foo".  However, as soon as the matching engine sees that there's
1601  no whitespace following the "Foo" that it had saved in $1, it realizes its
1602  mistake and starts over again one character after where it had the
1603  tentative match.  This time it goes all the way until the next occurrence
1604  of "foo". The complete regular expression matches this time, and you get
1605  the expected output of "table follows foo."
1606  
1607  Sometimes minimal matching can help a lot.  Imagine you'd like to match
1608  everything between "foo" and "bar".  Initially, you write something
1609  like this:
1610  
1611      $_ =  "The food is under the bar in the barn.";
1612      if ( /foo(.*)bar/ ) {
1613      print "got <$1>\n";
1614      }
1615  
1616  Which perhaps unexpectedly yields:
1617  
1618    got <d is under the bar in the >
1619  
1620  That's because C<.*> was greedy, so you get everything between the
1621  I<first> "foo" and the I<last> "bar".  Here it's more effective
1622  to use minimal matching to make sure you get the text between a "foo"
1623  and the first "bar" thereafter.
1624  
1625      if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1626    got <d is under the >
1627  
1628  Here's another example. Let's say you'd like to match a number at the end
1629  of a string, and you also want to keep the preceding part of the match.
1630  So you write this:
1631  
1632      $_ = "I have 2 numbers: 53147";
1633      if ( /(.*)(\d*)/ ) {                # Wrong!
1634      print "Beginning is <$1>, number is <$2>.\n";
1635      }
1636  
1637  That won't work at all, because C<.*> was greedy and gobbled up the
1638  whole string. As C<\d*> can match on an empty string the complete
1639  regular expression matched successfully.
1640  
1641      Beginning is <I have 2 numbers: 53147>, number is <>.
1642  
1643  Here are some variants, most of which don't work:
1644  
1645      $_ = "I have 2 numbers: 53147";
1646      @pats = qw{
1647      (.*)(\d*)
1648      (.*)(\d+)
1649      (.*?)(\d*)
1650      (.*?)(\d+)
1651      (.*)(\d+)$
1652      (.*?)(\d+)$
1653      (.*)\b(\d+)$
1654      (.*\D)(\d+)$
1655      };
1656  
1657      for $pat (@pats) {
1658      printf "%-12s ", $pat;
1659      if ( /$pat/ ) {
1660          print "<$1> <$2>\n";
1661      } else {
1662          print "FAIL\n";
1663      }
1664      }
1665  
1666  That will print out:
1667  
1668      (.*)(\d*)    <I have 2 numbers: 53147> <>
1669      (.*)(\d+)    <I have 2 numbers: 5314> <7>
1670      (.*?)(\d*)   <> <>
1671      (.*?)(\d+)   <I have > <2>
1672      (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1673      (.*?)(\d+)$  <I have 2 numbers: > <53147>
1674      (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1675      (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1676  
1677  As you see, this can be a bit tricky.  It's important to realize that a
1678  regular expression is merely a set of assertions that gives a definition
1679  of success.  There may be 0, 1, or several different ways that the
1680  definition might succeed against a particular string.  And if there are
1681  multiple ways it might succeed, you need to understand backtracking to
1682  know which variety of success you will achieve.
1683  
1684  When using look-ahead assertions and negations, this can all get even
1685  trickier.  Imagine you'd like to find a sequence of non-digits not
1686  followed by "123".  You might try to write that as
1687  
1688      $_ = "ABC123";
1689      if ( /^\D*(?!123)/ ) {        # Wrong!
1690      print "Yup, no 123 in $_\n";
1691      }
1692  
1693  But that isn't going to match; at least, not the way you're hoping.  It
1694  claims that there is no 123 in the string.  Here's a clearer picture of
1695  why that pattern matches, contrary to popular expectations:
1696  
1697      $x = 'ABC123';
1698      $y = 'ABC445';
1699  
1700      print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1701      print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1702  
1703      print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1704      print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1705  
1706  This prints
1707  
1708      2: got ABC
1709      3: got AB
1710      4: got ABC
1711  
1712  You might have expected test 3 to fail because it seems to a more
1713  general purpose version of test 1.  The important difference between
1714  them is that test 3 contains a quantifier (C<\D*>) and so can use
1715  backtracking, whereas test 1 will not.  What's happening is
1716  that you've asked "Is it true that at the start of $x, following 0 or more
1717  non-digits, you have something that's not 123?"  If the pattern matcher had
1718  let C<\D*> expand to "ABC", this would have caused the whole pattern to
1719  fail.
1720  
1721  The search engine will initially match C<\D*> with "ABC".  Then it will
1722  try to match C<(?!123> with "123", which fails.  But because
1723  a quantifier (C<\D*>) has been used in the regular expression, the
1724  search engine can backtrack and retry the match differently
1725  in the hope of matching the complete regular expression.
1726  
1727  The pattern really, I<really> wants to succeed, so it uses the
1728  standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1729  time.  Now there's indeed something following "AB" that is not
1730  "123".  It's "C123", which suffices.
1731  
1732  We can deal with this by using both an assertion and a negation.
1733  We'll say that the first part in $1 must be followed both by a digit
1734  and by something that's not "123".  Remember that the look-aheads
1735  are zero-width expressions--they only look, but don't consume any
1736  of the string in their match.  So rewriting this way produces what
1737  you'd expect; that is, case 5 will fail, but case 6 succeeds:
1738  
1739      print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1740      print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1741  
1742      6: got ABC
1743  
1744  In other words, the two zero-width assertions next to each other work as though
1745  they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1746  matches only if you're at the beginning of the line AND the end of the
1747  line simultaneously.  The deeper underlying truth is that juxtaposition in
1748  regular expressions always means AND, except when you write an explicit OR
1749  using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1750  although the attempted matches are made at different positions because "a"
1751  is not a zero-width assertion, but a one-width assertion.
1752  
1753  B<WARNING>: Particularly complicated regular expressions can take
1754  exponential time to solve because of the immense number of possible
1755  ways they can use backtracking to try for a match.  For example, without
1756  internal optimizations done by the regular expression engine, this will
1757  take a painfully long time to run:
1758  
1759      'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1760  
1761  And if you used C<*>'s in the internal groups instead of limiting them
1762  to 0 through 5 matches, then it would take forever--or until you ran
1763  out of stack space.  Moreover, these internal optimizations are not
1764  always applicable.  For example, if you put C<{0,5}> instead of C<*>
1765  on the external group, no current optimization is applicable, and the
1766  match takes a long time to finish.
1767  
1768  A powerful tool for optimizing such beasts is what is known as an
1769  "independent group",
1770  which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1771  zero-length look-ahead/look-behind assertions will not backtrack to make
1772  the tail match, since they are in "logical" context: only
1773  whether they match is considered relevant.  For an example
1774  where side-effects of look-ahead I<might> have influenced the
1775  following match, see L<C<< (?>pattern) >>>.
1776  
1777  =head2 Version 8 Regular Expressions
1778  X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1779  
1780  In case you're not familiar with the "regular" Version 8 regex
1781  routines, here are the pattern-matching rules not described above.
1782  
1783  Any single character matches itself, unless it is a I<metacharacter>
1784  with a special meaning described here or above.  You can cause
1785  characters that normally function as metacharacters to be interpreted
1786  literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1787  character; "\\" matches a "\"). This escape mechanism is also required
1788  for the character used as the pattern delimiter.
1789  
1790  A series of characters matches that series of characters in the target
1791  string, so the pattern  C<blurfl> would match "blurfl" in the target
1792  string.
1793  
1794  You can specify a character class, by enclosing a list of characters
1795  in C<[]>, which will match any character from the list.  If the
1796  first character after the "[" is "^", the class matches any character not
1797  in the list.  Within a list, the "-" character specifies a
1798  range, so that C<a-z> represents all characters between "a" and "z",
1799  inclusive.  If you want either "-" or "]" itself to be a member of a
1800  class, put it at the start of the list (possibly after a "^"), or
1801  escape it with a backslash.  "-" is also taken literally when it is
1802  at the end of the list, just before the closing "]".  (The
1803  following all specify the same class of three characters: C<[-az]>,
1804  C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1805  specifies a class containing twenty-six characters, even on EBCDIC-based
1806  character sets.)  Also, if you try to use the character
1807  classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1808  a range, the "-" is understood literally.
1809  
1810  Note also that the whole range idea is rather unportable between
1811  character sets--and even within character sets they may cause results
1812  you probably didn't expect.  A sound principle is to use only ranges
1813  that begin from and end at either alphabetics of equal case ([a-e],
1814  [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1815  spell out the character sets in full.
1816  
1817  Characters may be specified using a metacharacter syntax much like that
1818  used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1819  "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1820  of octal digits, matches the character whose coded character set value
1821  is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1822  matches the character whose numeric value is I<nn>. The expression \cI<x>
1823  matches the character control-I<x>.  Finally, the "." metacharacter
1824  matches any character except "\n" (unless you use C</s>).
1825  
1826  You can specify a series of alternatives for a pattern using "|" to
1827  separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1828  or "foe" in the target string (as would C<f(e|i|o)e>).  The
1829  first alternative includes everything from the last pattern delimiter
1830  ("(", "[", or the beginning of the pattern) up to the first "|", and
1831  the last alternative contains everything from the last "|" to the next
1832  pattern delimiter.  That's why it's common practice to include
1833  alternatives in parentheses: to minimize confusion about where they
1834  start and end.
1835  
1836  Alternatives are tried from left to right, so the first
1837  alternative found for which the entire expression matches, is the one that
1838  is chosen. This means that alternatives are not necessarily greedy. For
1839  example: when matching C<foo|foot> against "barefoot", only the "foo"
1840  part will match, as that is the first alternative tried, and it successfully
1841  matches the target string. (This might not seem important, but it is
1842  important when you are capturing matched text using parentheses.)
1843  
1844  Also remember that "|" is interpreted as a literal within square brackets,
1845  so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1846  
1847  Within a pattern, you may designate subpatterns for later reference
1848  by enclosing them in parentheses, and you may refer back to the
1849  I<n>th subpattern later in the pattern using the metacharacter
1850  \I<n>.  Subpatterns are numbered based on the left to right order
1851  of their opening parenthesis.  A backreference matches whatever
1852  actually matched the subpattern in the string being examined, not
1853  the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1854  match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1855  1 matched "0x", even though the rule C<0|0x> could potentially match
1856  the leading 0 in the second number.
1857  
1858  =head2 Warning on \1 Instead of $1
1859  
1860  Some people get too used to writing things like:
1861  
1862      $pattern =~ s/(\W)/\\\1/g;
1863  
1864  This is grandfathered for the RHS of a substitute to avoid shocking the
1865  B<sed> addicts, but it's a dirty habit to get into.  That's because in
1866  PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1867  the usual double-quoted string means a control-A.  The customary Unix
1868  meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1869  of doing that, you get yourself into trouble if you then add an C</e>
1870  modifier.
1871  
1872      s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1873  
1874  Or if you try to do
1875  
1876      s/(\d+)/\1000/;
1877  
1878  You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1879  C<$1}000>.  The operation of interpolation should not be confused
1880  with the operation of matching a backreference.  Certainly they mean two
1881  different things on the I<left> side of the C<s///>.
1882  
1883  =head2 Repeated Patterns Matching a Zero-length Substring
1884  
1885  B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1886  
1887  Regular expressions provide a terse and powerful programming language.  As
1888  with most other power tools, power comes together with the ability
1889  to wreak havoc.
1890  
1891  A common abuse of this power stems from the ability to make infinite
1892  loops using regular expressions, with something as innocuous as:
1893  
1894      'foo' =~ m{ ( o? )* }x;
1895  
1896  The C<o?> matches at the beginning of C<'foo'>, and since the position
1897  in the string is not moved by the match, C<o?> would match again and again
1898  because of the C<*> quantifier.  Another common way to create a similar cycle
1899  is with the looping modifier C<//g>:
1900  
1901      @matches = ( 'foo' =~ m{ o? }xg );
1902  
1903  or
1904  
1905      print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1906  
1907  or the loop implied by split().
1908  
1909  However, long experience has shown that many programming tasks may
1910  be significantly simplified by using repeated subexpressions that
1911  may match zero-length substrings.  Here's a simple example being:
1912  
1913      @chars = split //, $string;          # // is not magic in split
1914      ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1915  
1916  Thus Perl allows such constructs, by I<forcefully breaking
1917  the infinite loop>.  The rules for this are different for lower-level
1918  loops given by the greedy quantifiers C<*+{}>, and for higher-level
1919  ones like the C</g> modifier or split() operator.
1920  
1921  The lower-level loops are I<interrupted> (that is, the loop is
1922  broken) when Perl detects that a repeated expression matched a
1923  zero-length substring.   Thus
1924  
1925     m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1926  
1927  is made equivalent to
1928  
1929     m{   (?: NON_ZERO_LENGTH )*
1930        |
1931          (?: ZERO_LENGTH )?
1932      }x;
1933  
1934  The higher level-loops preserve an additional state between iterations:
1935  whether the last match was zero-length.  To break the loop, the following
1936  match after a zero-length match is prohibited to have a length of zero.
1937  This prohibition interacts with backtracking (see L<"Backtracking">),
1938  and so the I<second best> match is chosen if the I<best> match is of
1939  zero length.
1940  
1941  For example:
1942  
1943      $_ = 'bar';
1944      s/\w??/<$&>/g;
1945  
1946  results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1947  match given by non-greedy C<??> is the zero-length match, and the I<second
1948  best> match is what is matched by C<\w>.  Thus zero-length matches
1949  alternate with one-character-long matches.
1950  
1951  Similarly, for repeated C<m/()/g> the second-best match is the match at the
1952  position one notch further in the string.
1953  
1954  The additional state of being I<matched with zero-length> is associated with
1955  the matched string, and is reset by each assignment to pos().
1956  Zero-length matches at the end of the previous match are ignored
1957  during C<split>.
1958  
1959  =head2 Combining RE Pieces
1960  
1961  Each of the elementary pieces of regular expressions which were described
1962  before (such as C<ab> or C<\Z>) could match at most one substring
1963  at the given position of the input string.  However, in a typical regular
1964  expression these elementary pieces are combined into more complicated
1965  patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1966  (in these examples C<S> and C<T> are regular subexpressions).
1967  
1968  Such combinations can include alternatives, leading to a problem of choice:
1969  if we match a regular expression C<a|ab> against C<"abc">, will it match
1970  substring C<"a"> or C<"ab">?  One way to describe which substring is
1971  actually matched is the concept of backtracking (see L<"Backtracking">).
1972  However, this description is too low-level and makes you think
1973  in terms of a particular implementation.
1974  
1975  Another description starts with notions of "better"/"worse".  All the
1976  substrings which may be matched by the given regular expression can be
1977  sorted from the "best" match to the "worst" match, and it is the "best"
1978  match which is chosen.  This substitutes the question of "what is chosen?"
1979  by the question of "which matches are better, and which are worse?".
1980  
1981  Again, for elementary pieces there is no such question, since at most
1982  one match at a given position is possible.  This section describes the
1983  notion of better/worse for combining operators.  In the description
1984  below C<S> and C<T> are regular subexpressions.
1985  
1986  =over 4
1987  
1988  =item C<ST>
1989  
1990  Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1991  substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1992  which can be matched by C<T>.
1993  
1994  If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1995  match than C<A'B'>.
1996  
1997  If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
1998  C<B> is better match for C<T> than C<B'>.
1999  
2000  =item C<S|T>
2001  
2002  When C<S> can match, it is a better match than when only C<T> can match.
2003  
2004  Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2005  two matches for C<T>.
2006  
2007  =item C<S{REPEAT_COUNT}>
2008  
2009  Matches as C<SSS...S> (repeated as many times as necessary).
2010  
2011  =item C<S{min,max}>
2012  
2013  Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2014  
2015  =item C<S{min,max}?>
2016  
2017  Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2018  
2019  =item C<S?>, C<S*>, C<S+>
2020  
2021  Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2022  
2023  =item C<S??>, C<S*?>, C<S+?>
2024  
2025  Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2026  
2027  =item C<< (?>S) >>
2028  
2029  Matches the best match for C<S> and only that.
2030  
2031  =item C<(?=S)>, C<(?<=S)>
2032  
2033  Only the best match for C<S> is considered.  (This is important only if
2034  C<S> has capturing parentheses, and backreferences are used somewhere
2035  else in the whole regular expression.)
2036  
2037  =item C<(?!S)>, C<(?<!S)>
2038  
2039  For this grouping operator there is no need to describe the ordering, since
2040  only whether or not C<S> can match is important.
2041  
2042  =item C<(??{ EXPR })>, C<(?PARNO)>
2043  
2044  The ordering is the same as for the regular expression which is
2045  the result of EXPR, or the pattern contained by capture buffer PARNO.
2046  
2047  =item C<(?(condition)yes-pattern|no-pattern)>
2048  
2049  Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2050  already determined.  The ordering of the matches is the same as for the
2051  chosen subexpression.
2052  
2053  =back
2054  
2055  The above recipes describe the ordering of matches I<at a given position>.
2056  One more rule is needed to understand how a match is determined for the
2057  whole regular expression: a match at an earlier position is always better
2058  than a match at a later position.
2059  
2060  =head2 Creating Custom RE Engines
2061  
2062  Overloaded constants (see L<overload>) provide a simple way to extend
2063  the functionality of the RE engine.
2064  
2065  Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2066  matches at a boundary between whitespace characters and non-whitespace
2067  characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2068  at these positions, so we want to have each C<\Y|> in the place of the
2069  more complicated version.  We can create a module C<customre> to do
2070  this:
2071  
2072      package customre;
2073      use overload;
2074  
2075      sub import {
2076        shift;
2077        die "No argument to customre::import allowed" if @_;
2078        overload::constant 'qr' => \&convert;
2079      }
2080  
2081      sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2082  
2083      # We must also take care of not escaping the legitimate \\Y|
2084      # sequence, hence the presence of '\\' in the conversion rules.
2085      my %rules = ( '\\' => '\\\\',
2086            'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2087      sub convert {
2088        my $re = shift;
2089        $re =~ s{
2090                  \\ ( \\ | Y . )
2091                }
2092                { $rules{$1} or invalid($re,$1) }sgex;
2093        return $re;
2094      }
2095  
2096  Now C<use customre> enables the new escape in constant regular
2097  expressions, i.e., those without any runtime variable interpolations.
2098  As documented in L<overload>, this conversion will work only over
2099  literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2100  part of this regular expression needs to be converted explicitly
2101  (but only if the special meaning of C<\Y|> should be enabled inside $re):
2102  
2103      use customre;
2104      $re = <>;
2105      chomp $re;
2106      $re = customre::convert $re;
2107      /\Y|$re\Y|/;
2108  
2109  =head1 PCRE/Python Support
2110  
2111  As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2112  to the regex syntax. While Perl programmers are encouraged to use the
2113  Perl specific syntax, the following are also accepted:
2114  
2115  =over 4
2116  
2117  =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2118  
2119  Define a named capture buffer. Equivalent to C<< (?<NAME>pattern) >>.
2120  
2121  =item C<< (?P=NAME) >>
2122  
2123  Backreference to a named capture buffer. Equivalent to C<< \g{NAME} >>.
2124  
2125  =item C<< (?P>NAME) >>
2126  
2127  Subroutine call to a named capture buffer. Equivalent to C<< (?&NAME) >>.
2128  
2129  =back
2130  
2131  =head1 BUGS
2132  
2133  This document varies from difficult to understand to completely
2134  and utterly opaque.  The wandering prose riddled with jargon is
2135  hard to fathom in several places.
2136  
2137  This document needs a rewrite that separates the tutorial content
2138  from the reference content.
2139  
2140  =head1 SEE ALSO
2141  
2142  L<perlrequick>.
2143  
2144  L<perlretut>.
2145  
2146  L<perlop/"Regexp Quote-Like Operators">.
2147  
2148  L<perlop/"Gory details of parsing quoted constructs">.
2149  
2150  L<perlfaq6>.
2151  
2152  L<perlfunc/pos>.
2153  
2154  L<perllocale>.
2155  
2156  L<perlebcdic>.
2157  
2158  I<Mastering Regular Expressions> by Jeffrey Friedl, published
2159  by O'Reilly and Associates.