[ Index ]

PHP Cross Reference of Unnamed Project

title

Body

[close]

/se3-unattended/var/se3/unattended/install/linuxaux/opt/perl/lib/5.10.0/pod/ -> perlfaq4.pod (source)

   1  =head1 NAME
   2  
   3  perlfaq4 - Data Manipulation ($Revision: 10394 $)
   4  
   5  =head1 DESCRIPTION
   6  
   7  This section of the FAQ answers questions related to manipulating
   8  numbers, dates, strings, arrays, hashes, and miscellaneous data issues.
   9  
  10  =head1 Data: Numbers
  11  
  12  =head2 Why am I getting long decimals (eg, 19.9499999999999) instead of the numbers I should be getting (eg, 19.95)?
  13  
  14  Internally, your computer represents floating-point numbers in binary.
  15  Digital (as in powers of two) computers cannot store all numbers
  16  exactly.  Some real numbers lose precision in the process.  This is a
  17  problem with how computers store numbers and affects all computer
  18  languages, not just Perl.
  19  
  20  L<perlnumber> shows the gory details of number representations and
  21  conversions.
  22  
  23  To limit the number of decimal places in your numbers, you can use the
  24  printf or sprintf function.  See the L<"Floating Point
  25  Arithmetic"|perlop> for more details.
  26  
  27      printf "%.2f", 10/3;
  28  
  29      my $number = sprintf "%.2f", 10/3;
  30  
  31  =head2 Why is int() broken?
  32  
  33  Your C<int()> is most probably working just fine.  It's the numbers that
  34  aren't quite what you think.
  35  
  36  First, see the answer to "Why am I getting long decimals
  37  (eg, 19.9499999999999) instead of the numbers I should be getting
  38  (eg, 19.95)?".
  39  
  40  For example, this
  41  
  42      print int(0.6/0.2-2), "\n";
  43  
  44  will in most computers print 0, not 1, because even such simple
  45  numbers as 0.6 and 0.2 cannot be presented exactly by floating-point
  46  numbers.  What you think in the above as 'three' is really more like
  47  2.9999999999999995559.
  48  
  49  =head2 Why isn't my octal data interpreted correctly?
  50  
  51  Perl only understands octal and hex numbers as such when they occur as
  52  literals in your program.  Octal literals in perl must start with a
  53  leading C<0> and hexadecimal literals must start with a leading C<0x>.
  54  If they are read in from somewhere and assigned, no automatic
  55  conversion takes place.  You must explicitly use C<oct()> or C<hex()> if you
  56  want the values converted to decimal.  C<oct()> interprets hexadecimal (C<0x350>),
  57  octal (C<0350> or even without the leading C<0>, like C<377>) and binary
  58  (C<0b1010>) numbers, while C<hex()> only converts hexadecimal ones, with
  59  or without a leading C<0x>, such as C<0x255>, C<3A>, C<ff>, or C<deadbeef>.
  60  The inverse mapping from decimal to octal can be done with either the
  61  <%o> or C<%O> C<sprintf()> formats.
  62  
  63  This problem shows up most often when people try using C<chmod()>,
  64  C<mkdir()>, C<umask()>, or C<sysopen()>, which by widespread tradition
  65  typically take permissions in octal.
  66  
  67      chmod(644,  $file);   # WRONG
  68      chmod(0644, $file);   # right
  69  
  70  Note the mistake in the first line was specifying the decimal literal
  71  C<644>, rather than the intended octal literal C<0644>.  The problem can
  72  be seen with:
  73  
  74      printf("%#o",644);   # prints 01204
  75  
  76  Surely you had not intended C<chmod(01204, $file);> - did you?  If you
  77  want to use numeric literals as arguments to chmod() et al. then please
  78  try to express them as octal constants, that is with a leading zero and
  79  with the following digits restricted to the set C<0..7>.
  80  
  81  =head2 Does Perl have a round() function?  What about ceil() and floor()?  Trig functions?
  82  
  83  Remember that C<int()> merely truncates toward 0.  For rounding to a
  84  certain number of digits, C<sprintf()> or C<printf()> is usually the
  85  easiest route.
  86  
  87      printf("%.3f", 3.1415926535);   # prints 3.142
  88  
  89  The C<POSIX> module (part of the standard Perl distribution)
  90  implements C<ceil()>, C<floor()>, and a number of other mathematical
  91  and trigonometric functions.
  92  
  93      use POSIX;
  94      $ceil   = ceil(3.5);   # 4
  95      $floor  = floor(3.5);  # 3
  96  
  97  In 5.000 to 5.003 perls, trigonometry was done in the C<Math::Complex>
  98  module.  With 5.004, the C<Math::Trig> module (part of the standard Perl
  99  distribution) implements the trigonometric functions. Internally it
 100  uses the C<Math::Complex> module and some functions can break out from
 101  the real axis into the complex plane, for example the inverse sine of
 102  2.
 103  
 104  Rounding in financial applications can have serious implications, and
 105  the rounding method used should be specified precisely.  In these
 106  cases, it probably pays not to trust whichever system rounding is
 107  being used by Perl, but to instead implement the rounding function you
 108  need yourself.
 109  
 110  To see why, notice how you'll still have an issue on half-way-point
 111  alternation:
 112  
 113      for ($i = 0; $i < 1.01; $i += 0.05) { printf "%.1f ",$i}
 114  
 115      0.0 0.1 0.1 0.2 0.2 0.2 0.3 0.3 0.4 0.4 0.5 0.5 0.6 0.7 0.7
 116      0.8 0.8 0.9 0.9 1.0 1.0
 117  
 118  Don't blame Perl.  It's the same as in C.  IEEE says we have to do
 119  this. Perl numbers whose absolute values are integers under 2**31 (on
 120  32 bit machines) will work pretty much like mathematical integers.
 121  Other numbers are not guaranteed.
 122  
 123  =head2 How do I convert between numeric representations/bases/radixes?
 124  
 125  As always with Perl there is more than one way to do it.  Below are a
 126  few examples of approaches to making common conversions between number
 127  representations.  This is intended to be representational rather than
 128  exhaustive.
 129  
 130  Some of the examples later in L<perlfaq4> use the C<Bit::Vector>
 131  module from CPAN. The reason you might choose C<Bit::Vector> over the
 132  perl built in functions is that it works with numbers of ANY size,
 133  that it is optimized for speed on some operations, and for at least
 134  some programmers the notation might be familiar.
 135  
 136  =over 4
 137  
 138  =item How do I convert hexadecimal into decimal
 139  
 140  Using perl's built in conversion of C<0x> notation:
 141  
 142      $dec = 0xDEADBEEF;
 143  
 144  Using the C<hex> function:
 145  
 146      $dec = hex("DEADBEEF");
 147  
 148  Using C<pack>:
 149  
 150      $dec = unpack("N", pack("H8", substr("0" x 8 . "DEADBEEF", -8)));
 151  
 152  Using the CPAN module C<Bit::Vector>:
 153  
 154      use Bit::Vector;
 155      $vec = Bit::Vector->new_Hex(32, "DEADBEEF");
 156      $dec = $vec->to_Dec();
 157  
 158  =item How do I convert from decimal to hexadecimal
 159  
 160  Using C<sprintf>:
 161  
 162      $hex = sprintf("%X", 3735928559); # upper case A-F
 163      $hex = sprintf("%x", 3735928559); # lower case a-f
 164  
 165  Using C<unpack>:
 166  
 167      $hex = unpack("H*", pack("N", 3735928559));
 168  
 169  Using C<Bit::Vector>:
 170  
 171      use Bit::Vector;
 172      $vec = Bit::Vector->new_Dec(32, -559038737);
 173      $hex = $vec->to_Hex();
 174  
 175  And C<Bit::Vector> supports odd bit counts:
 176  
 177      use Bit::Vector;
 178      $vec = Bit::Vector->new_Dec(33, 3735928559);
 179      $vec->Resize(32); # suppress leading 0 if unwanted
 180      $hex = $vec->to_Hex();
 181  
 182  =item How do I convert from octal to decimal
 183  
 184  Using Perl's built in conversion of numbers with leading zeros:
 185  
 186      $dec = 033653337357; # note the leading 0!
 187  
 188  Using the C<oct> function:
 189  
 190      $dec = oct("33653337357");
 191  
 192  Using C<Bit::Vector>:
 193  
 194      use Bit::Vector;
 195      $vec = Bit::Vector->new(32);
 196      $vec->Chunk_List_Store(3, split(//, reverse "33653337357"));
 197      $dec = $vec->to_Dec();
 198  
 199  =item How do I convert from decimal to octal
 200  
 201  Using C<sprintf>:
 202  
 203      $oct = sprintf("%o", 3735928559);
 204  
 205  Using C<Bit::Vector>:
 206  
 207      use Bit::Vector;
 208      $vec = Bit::Vector->new_Dec(32, -559038737);
 209      $oct = reverse join('', $vec->Chunk_List_Read(3));
 210  
 211  =item How do I convert from binary to decimal
 212  
 213  Perl 5.6 lets you write binary numbers directly with
 214  the C<0b> notation:
 215  
 216      $number = 0b10110110;
 217  
 218  Using C<oct>:
 219  
 220      my $input = "10110110";
 221      $decimal = oct( "0b$input" );
 222  
 223  Using C<pack> and C<ord>:
 224  
 225      $decimal = ord(pack('B8', '10110110'));
 226  
 227  Using C<pack> and C<unpack> for larger strings:
 228  
 229      $int = unpack("N", pack("B32",
 230      substr("0" x 32 . "11110101011011011111011101111", -32)));
 231      $dec = sprintf("%d", $int);
 232  
 233      # substr() is used to left pad a 32 character string with zeros.
 234  
 235  Using C<Bit::Vector>:
 236  
 237      $vec = Bit::Vector->new_Bin(32, "11011110101011011011111011101111");
 238      $dec = $vec->to_Dec();
 239  
 240  =item How do I convert from decimal to binary
 241  
 242  Using C<sprintf> (perl 5.6+):
 243  
 244      $bin = sprintf("%b", 3735928559);
 245  
 246  Using C<unpack>:
 247  
 248      $bin = unpack("B*", pack("N", 3735928559));
 249  
 250  Using C<Bit::Vector>:
 251  
 252      use Bit::Vector;
 253      $vec = Bit::Vector->new_Dec(32, -559038737);
 254      $bin = $vec->to_Bin();
 255  
 256  The remaining transformations (e.g. hex -> oct, bin -> hex, etc.)
 257  are left as an exercise to the inclined reader.
 258  
 259  =back
 260  
 261  =head2 Why doesn't & work the way I want it to?
 262  
 263  The behavior of binary arithmetic operators depends on whether they're
 264  used on numbers or strings.  The operators treat a string as a series
 265  of bits and work with that (the string C<"3"> is the bit pattern
 266  C<00110011>).  The operators work with the binary form of a number
 267  (the number C<3> is treated as the bit pattern C<00000011>).
 268  
 269  So, saying C<11 & 3> performs the "and" operation on numbers (yielding
 270  C<3>).  Saying C<"11" & "3"> performs the "and" operation on strings
 271  (yielding C<"1">).
 272  
 273  Most problems with C<&> and C<|> arise because the programmer thinks
 274  they have a number but really it's a string.  The rest arise because
 275  the programmer says:
 276  
 277      if ("\020\020" & "\101\101") {
 278          # ...
 279          }
 280  
 281  but a string consisting of two null bytes (the result of C<"\020\020"
 282  & "\101\101">) is not a false value in Perl.  You need:
 283  
 284      if ( ("\020\020" & "\101\101") !~ /[^\000]/) {
 285          # ...
 286          }
 287  
 288  =head2 How do I multiply matrices?
 289  
 290  Use the Math::Matrix or Math::MatrixReal modules (available from CPAN)
 291  or the PDL extension (also available from CPAN).
 292  
 293  =head2 How do I perform an operation on a series of integers?
 294  
 295  To call a function on each element in an array, and collect the
 296  results, use:
 297  
 298      @results = map { my_func($_) } @array;
 299  
 300  For example:
 301  
 302      @triple = map { 3 * $_ } @single;
 303  
 304  To call a function on each element of an array, but ignore the
 305  results:
 306  
 307      foreach $iterator (@array) {
 308          some_func($iterator);
 309          }
 310  
 311  To call a function on each integer in a (small) range, you B<can> use:
 312  
 313      @results = map { some_func($_) } (5 .. 25);
 314  
 315  but you should be aware that the C<..> operator creates an array of
 316  all integers in the range.  This can take a lot of memory for large
 317  ranges.  Instead use:
 318  
 319      @results = ();
 320      for ($i=5; $i < 500_005; $i++) {
 321          push(@results, some_func($i));
 322          }
 323  
 324  This situation has been fixed in Perl5.005. Use of C<..> in a C<for>
 325  loop will iterate over the range, without creating the entire range.
 326  
 327      for my $i (5 .. 500_005) {
 328          push(@results, some_func($i));
 329          }
 330  
 331  will not create a list of 500,000 integers.
 332  
 333  =head2 How can I output Roman numerals?
 334  
 335  Get the http://www.cpan.org/modules/by-module/Roman module.
 336  
 337  =head2 Why aren't my random numbers random?
 338  
 339  If you're using a version of Perl before 5.004, you must call C<srand>
 340  once at the start of your program to seed the random number generator.
 341  
 342       BEGIN { srand() if $] < 5.004 }
 343  
 344  5.004 and later automatically call C<srand> at the beginning.  Don't
 345  call C<srand> more than once--you make your numbers less random,
 346  rather than more.
 347  
 348  Computers are good at being predictable and bad at being random
 349  (despite appearances caused by bugs in your programs :-).  see the
 350  F<random> article in the "Far More Than You Ever Wanted To Know"
 351  collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz , courtesy
 352  of Tom Phoenix, talks more about this.  John von Neumann said, "Anyone
 353  who attempts to generate random numbers by deterministic means is, of
 354  course, living in a state of sin."
 355  
 356  If you want numbers that are more random than C<rand> with C<srand>
 357  provides, you should also check out the C<Math::TrulyRandom> module from
 358  CPAN.  It uses the imperfections in your system's timer to generate
 359  random numbers, but this takes quite a while.  If you want a better
 360  pseudorandom generator than comes with your operating system, look at
 361  "Numerical Recipes in C" at http://www.nr.com/ .
 362  
 363  =head2 How do I get a random number between X and Y?
 364  
 365  To get a random number between two values, you can use the C<rand()>
 366  builtin to get a random number between 0 and 1. From there, you shift
 367  that into the range that you want.
 368  
 369  C<rand($x)> returns a number such that C<< 0 <= rand($x) < $x >>. Thus
 370  what you want to have perl figure out is a random number in the range
 371  from 0 to the difference between your I<X> and I<Y>.
 372  
 373  That is, to get a number between 10 and 15, inclusive, you want a
 374  random number between 0 and 5 that you can then add to 10.
 375  
 376      my $number = 10 + int rand( 15-10+1 );
 377  
 378  Hence you derive the following simple function to abstract
 379  that. It selects a random integer between the two given
 380  integers (inclusive), For example: C<random_int_between(50,120)>.
 381  
 382      sub random_int_between {
 383          my($min, $max) = @_;
 384          # Assumes that the two arguments are integers themselves!
 385          return $min if $min == $max;
 386          ($min, $max) = ($max, $min)  if  $min > $max;
 387          return $min + int rand(1 + $max - $min);
 388          }
 389  
 390  =head1 Data: Dates
 391  
 392  =head2 How do I find the day or week of the year?
 393  
 394  The localtime function returns the day of the year.  Without an
 395  argument localtime uses the current time.
 396  
 397      $day_of_year = (localtime)[7];
 398  
 399  The C<POSIX> module can also format a date as the day of the year or
 400  week of the year.
 401  
 402      use POSIX qw/strftime/;
 403      my $day_of_year  = strftime "%j", localtime;
 404      my $week_of_year = strftime "%W", localtime;
 405  
 406  To get the day of year for any date, use C<POSIX>'s C<mktime> to get
 407  a time in epoch seconds for the argument to localtime.
 408  
 409      use POSIX qw/mktime strftime/;
 410      my $week_of_year = strftime "%W",
 411          localtime( mktime( 0, 0, 0, 18, 11, 87 ) );
 412  
 413  The C<Date::Calc> module provides two functions to calculate these.
 414  
 415      use Date::Calc;
 416      my $day_of_year  = Day_of_Year(  1987, 12, 18 );
 417      my $week_of_year = Week_of_Year( 1987, 12, 18 );
 418  
 419  =head2 How do I find the current century or millennium?
 420  
 421  Use the following simple functions:
 422  
 423      sub get_century    {
 424          return int((((localtime(shift || time))[5] + 1999))/100);
 425          }
 426  
 427      sub get_millennium {
 428          return 1+int((((localtime(shift || time))[5] + 1899))/1000);
 429          }
 430  
 431  On some systems, the C<POSIX> module's C<strftime()> function has been
 432  extended in a non-standard way to use a C<%C> format, which they
 433  sometimes claim is the "century". It isn't, because on most such
 434  systems, this is only the first two digits of the four-digit year, and
 435  thus cannot be used to reliably determine the current century or
 436  millennium.
 437  
 438  =head2 How can I compare two dates and find the difference?
 439  
 440  (contributed by brian d foy)
 441  
 442  You could just store all your dates as a number and then subtract.
 443  Life isn't always that simple though. If you want to work with
 444  formatted dates, the C<Date::Manip>, C<Date::Calc>, or C<DateTime>
 445  modules can help you.
 446  
 447  =head2 How can I take a string and turn it into epoch seconds?
 448  
 449  If it's a regular enough string that it always has the same format,
 450  you can split it up and pass the parts to C<timelocal> in the standard
 451  C<Time::Local> module.  Otherwise, you should look into the C<Date::Calc>
 452  and C<Date::Manip> modules from CPAN.
 453  
 454  =head2 How can I find the Julian Day?
 455  
 456  (contributed by brian d foy and Dave Cross)
 457  
 458  You can use the C<Time::JulianDay> module available on CPAN.  Ensure
 459  that you really want to find a Julian day, though, as many people have
 460  different ideas about Julian days.  See
 461  http://www.hermetic.ch/cal_stud/jdn.htm for instance.
 462  
 463  You can also try the C<DateTime> module, which can convert a date/time
 464  to a Julian Day.
 465  
 466      $ perl -MDateTime -le'print DateTime->today->jd'
 467      2453401.5
 468  
 469  Or the modified Julian Day
 470  
 471      $ perl -MDateTime -le'print DateTime->today->mjd'
 472      53401
 473  
 474  Or even the day of the year (which is what some people think of as a
 475  Julian day)
 476  
 477      $ perl -MDateTime -le'print DateTime->today->doy'
 478      31
 479  
 480  =head2 How do I find yesterday's date?
 481  
 482  (contributed by brian d foy)
 483  
 484  Use one of the Date modules. The C<DateTime> module makes it simple, and
 485  give you the same time of day, only the day before.
 486  
 487      use DateTime;
 488  
 489      my $yesterday = DateTime->now->subtract( days => 1 );
 490  
 491      print "Yesterday was $yesterday\n";
 492  
 493  You can also use the C<Date::Calc> module using its C<Today_and_Now>
 494  function.
 495  
 496      use Date::Calc qw( Today_and_Now Add_Delta_DHMS );
 497  
 498      my @date_time = Add_Delta_DHMS( Today_and_Now(), -1, 0, 0, 0 );
 499  
 500      print "@date_time\n";
 501  
 502  Most people try to use the time rather than the calendar to figure out
 503  dates, but that assumes that days are twenty-four hours each.  For
 504  most people, there are two days a year when they aren't: the switch to
 505  and from summer time throws this off. Let the modules do the work.
 506  
 507  =head2 Does Perl have a Year 2000 problem? Is Perl Y2K compliant?
 508  
 509  Short answer: No, Perl does not have a Year 2000 problem.  Yes, Perl is
 510  Y2K compliant (whatever that means). The programmers you've hired to
 511  use it, however, probably are not.
 512  
 513  Long answer: The question belies a true understanding of the issue.
 514  Perl is just as Y2K compliant as your pencil--no more, and no less.
 515  Can you use your pencil to write a non-Y2K-compliant memo?  Of course
 516  you can.  Is that the pencil's fault?  Of course it isn't.
 517  
 518  The date and time functions supplied with Perl (gmtime and localtime)
 519  supply adequate information to determine the year well beyond 2000
 520  (2038 is when trouble strikes for 32-bit machines).  The year returned
 521  by these functions when used in a list context is the year minus 1900.
 522  For years between 1910 and 1999 this I<happens> to be a 2-digit decimal
 523  number. To avoid the year 2000 problem simply do not treat the year as
 524  a 2-digit number.  It isn't.
 525  
 526  When gmtime() and localtime() are used in scalar context they return
 527  a timestamp string that contains a fully-expanded year.  For example,
 528  C<$timestamp = gmtime(1005613200)> sets $timestamp to "Tue Nov 13 01:00:00
 529  2001".  There's no year 2000 problem here.
 530  
 531  That doesn't mean that Perl can't be used to create non-Y2K compliant
 532  programs.  It can.  But so can your pencil.  It's the fault of the user,
 533  not the language.  At the risk of inflaming the NRA: "Perl doesn't
 534  break Y2K, people do."  See http://www.perl.org/about/y2k.html for
 535  a longer exposition.
 536  
 537  =head1 Data: Strings
 538  
 539  =head2 How do I validate input?
 540  
 541  (contributed by brian d foy)
 542  
 543  There are many ways to ensure that values are what you expect or
 544  want to accept. Besides the specific examples that we cover in the
 545  perlfaq, you can also look at the modules with "Assert" and "Validate"
 546  in their names, along with other modules such as C<Regexp::Common>.
 547  
 548  Some modules have validation for particular types of input, such
 549  as C<Business::ISBN>, C<Business::CreditCard>, C<Email::Valid>,
 550  and C<Data::Validate::IP>.
 551  
 552  =head2 How do I unescape a string?
 553  
 554  It depends just what you mean by "escape".  URL escapes are dealt
 555  with in L<perlfaq9>.  Shell escapes with the backslash (C<\>)
 556  character are removed with
 557  
 558      s/\\(.)/$1/g;
 559  
 560  This won't expand C<"\n"> or C<"\t"> or any other special escapes.
 561  
 562  =head2 How do I remove consecutive pairs of characters?
 563  
 564  (contributed by brian d foy)
 565  
 566  You can use the substitution operator to find pairs of characters (or
 567  runs of characters) and replace them with a single instance. In this
 568  substitution, we find a character in C<(.)>. The memory parentheses
 569  store the matched character in the back-reference C<\1> and we use
 570  that to require that the same thing immediately follow it. We replace
 571  that part of the string with the character in C<$1>.
 572  
 573      s/(.)\1/$1/g;
 574  
 575  We can also use the transliteration operator, C<tr///>. In this
 576  example, the search list side of our C<tr///> contains nothing, but
 577  the C<c> option complements that so it contains everything. The
 578  replacement list also contains nothing, so the transliteration is
 579  almost a no-op since it won't do any replacements (or more exactly,
 580  replace the character with itself). However, the C<s> option squashes
 581  duplicated and consecutive characters in the string so a character
 582  does not show up next to itself
 583  
 584      my $str = 'Haarlem';   # in the Netherlands
 585      $str =~ tr///cs;       # Now Harlem, like in New York
 586  
 587  =head2 How do I expand function calls in a string?
 588  
 589  (contributed by brian d foy)
 590  
 591  This is documented in L<perlref>, and although it's not the easiest
 592  thing to read, it does work. In each of these examples, we call the
 593  function inside the braces used to dereference a reference. If we
 594  have more than one return value, we can construct and dereference an
 595  anonymous array. In this case, we call the function in list context.
 596  
 597      print "The time values are @{ [localtime] }.\n";
 598  
 599  If we want to call the function in scalar context, we have to do a bit
 600  more work. We can really have any code we like inside the braces, so
 601  we simply have to end with the scalar reference, although how you do
 602  that is up to you, and you can use code inside the braces. Note that
 603  the use of parens creates a list context, so we need C<scalar> to
 604  force the scalar context on the function:
 605  
 606      print "The time is ${\(scalar localtime)}.\n"
 607  
 608      print "The time is ${ my $x = localtime; \$x }.\n";
 609  
 610  If your function already returns a reference, you don't need to create
 611  the reference yourself.
 612  
 613      sub timestamp { my $t = localtime; \$t }
 614  
 615      print "The time is ${ timestamp() }.\n";
 616  
 617  The C<Interpolation> module can also do a lot of magic for you. You can
 618  specify a variable name, in this case C<E>, to set up a tied hash that
 619  does the interpolation for you. It has several other methods to do this
 620  as well.
 621  
 622      use Interpolation E => 'eval';
 623      print "The time values are $E{localtime()}.\n";
 624  
 625  In most cases, it is probably easier to simply use string concatenation,
 626  which also forces scalar context.
 627  
 628      print "The time is " . localtime() . ".\n";
 629  
 630  =head2 How do I find matching/nesting anything?
 631  
 632  This isn't something that can be done in one regular expression, no
 633  matter how complicated.  To find something between two single
 634  characters, a pattern like C</x([^x]*)x/> will get the intervening
 635  bits in $1. For multiple ones, then something more like
 636  C</alpha(.*?)omega/> would be needed. But none of these deals with
 637  nested patterns.  For balanced expressions using C<(>, C<{>, C<[> or
 638  C<< < >> as delimiters, use the CPAN module Regexp::Common, or see
 639  L<perlre/(??{ code })>.  For other cases, you'll have to write a
 640  parser.
 641  
 642  If you are serious about writing a parser, there are a number of
 643  modules or oddities that will make your life a lot easier.  There are
 644  the CPAN modules C<Parse::RecDescent>, C<Parse::Yapp>, and
 645  C<Text::Balanced>; and the C<byacc> program. Starting from perl 5.8
 646  the C<Text::Balanced> is part of the standard distribution.
 647  
 648  One simple destructive, inside-out approach that you might try is to
 649  pull out the smallest nesting parts one at a time:
 650  
 651      while (s/BEGIN((?:(?!BEGIN)(?!END).)*)END//gs) {
 652          # do something with $1
 653          }
 654  
 655  A more complicated and sneaky approach is to make Perl's regular
 656  expression engine do it for you.  This is courtesy Dean Inada, and
 657  rather has the nature of an Obfuscated Perl Contest entry, but it
 658  really does work:
 659  
 660      # $_ contains the string to parse
 661      # BEGIN and END are the opening and closing markers for the
 662      # nested text.
 663  
 664      @( = ('(','');
 665      @) = (')','');
 666      ($re=$_)=~s/((BEGIN)|(END)|.)/$)[!$3]\Q$1\E$([!$2]/gs;
 667      @$ = (eval{/$re/},$@!~/unmatched/i);
 668      print join("\n",@$[0..$#$]) if( $$[-1] );
 669  
 670  =head2 How do I reverse a string?
 671  
 672  Use C<reverse()> in scalar context, as documented in
 673  L<perlfunc/reverse>.
 674  
 675      $reversed = reverse $string;
 676  
 677  =head2 How do I expand tabs in a string?
 678  
 679  You can do it yourself:
 680  
 681      1 while $string =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e;
 682  
 683  Or you can just use the C<Text::Tabs> module (part of the standard Perl
 684  distribution).
 685  
 686      use Text::Tabs;
 687      @expanded_lines = expand(@lines_with_tabs);
 688  
 689  =head2 How do I reformat a paragraph?
 690  
 691  Use C<Text::Wrap> (part of the standard Perl distribution):
 692  
 693      use Text::Wrap;
 694      print wrap("\t", '  ', @paragraphs);
 695  
 696  The paragraphs you give to C<Text::Wrap> should not contain embedded
 697  newlines.  C<Text::Wrap> doesn't justify the lines (flush-right).
 698  
 699  Or use the CPAN module C<Text::Autoformat>.  Formatting files can be
 700  easily done by making a shell alias, like so:
 701  
 702      alias fmt="perl -i -MText::Autoformat -n0777 \
 703          -e 'print autoformat $_, {all=>1}' $*"
 704  
 705  See the documentation for C<Text::Autoformat> to appreciate its many
 706  capabilities.
 707  
 708  =head2 How can I access or change N characters of a string?
 709  
 710  You can access the first characters of a string with substr().
 711  To get the first character, for example, start at position 0
 712  and grab the string of length 1.
 713  
 714  
 715      $string = "Just another Perl Hacker";
 716      $first_char = substr( $string, 0, 1 );  #  'J'
 717  
 718  To change part of a string, you can use the optional fourth
 719  argument which is the replacement string.
 720  
 721      substr( $string, 13, 4, "Perl 5.8.0" );
 722  
 723  You can also use substr() as an lvalue.
 724  
 725      substr( $string, 13, 4 ) =  "Perl 5.8.0";
 726  
 727  =head2 How do I change the Nth occurrence of something?
 728  
 729  You have to keep track of N yourself.  For example, let's say you want
 730  to change the fifth occurrence of C<"whoever"> or C<"whomever"> into
 731  C<"whosoever"> or C<"whomsoever">, case insensitively.  These
 732  all assume that $_ contains the string to be altered.
 733  
 734      $count = 0;
 735      s{((whom?)ever)}{
 736      ++$count == 5       # is it the 5th?
 737          ? "$2}soever"  # yes, swap
 738          : $1            # renege and leave it there
 739          }ige;
 740  
 741  In the more general case, you can use the C</g> modifier in a C<while>
 742  loop, keeping count of matches.
 743  
 744      $WANT = 3;
 745      $count = 0;
 746      $_ = "One fish two fish red fish blue fish";
 747      while (/(\w+)\s+fish\b/gi) {
 748          if (++$count == $WANT) {
 749              print "The third fish is a $1 one.\n";
 750              }
 751          }
 752  
 753  That prints out: C<"The third fish is a red one.">  You can also use a
 754  repetition count and repeated pattern like this:
 755  
 756      /(?:\w+\s+fish\s+){2}(\w+)\s+fish/i;
 757  
 758  =head2 How can I count the number of occurrences of a substring within a string?
 759  
 760  There are a number of ways, with varying efficiency.  If you want a
 761  count of a certain single character (X) within a string, you can use the
 762  C<tr///> function like so:
 763  
 764      $string = "ThisXlineXhasXsomeXx'sXinXit";
 765      $count = ($string =~ tr/X//);
 766      print "There are $count X characters in the string";
 767  
 768  This is fine if you are just looking for a single character.  However,
 769  if you are trying to count multiple character substrings within a
 770  larger string, C<tr///> won't work.  What you can do is wrap a while()
 771  loop around a global pattern match.  For example, let's count negative
 772  integers:
 773  
 774      $string = "-9 55 48 -2 23 -76 4 14 -44";
 775      while ($string =~ /-\d+/g) { $count++ }
 776      print "There are $count negative numbers in the string";
 777  
 778  Another version uses a global match in list context, then assigns the
 779  result to a scalar, producing a count of the number of matches.
 780  
 781      $count = () = $string =~ /-\d+/g;
 782  
 783  =head2 How do I capitalize all the words on one line?
 784  
 785  To make the first letter of each word upper case:
 786  
 787      $line =~ s/\b(\w)/\U$1/g;
 788  
 789  This has the strange effect of turning "C<don't do it>" into "C<Don'T
 790  Do It>".  Sometimes you might want this.  Other times you might need a
 791  more thorough solution (Suggested by brian d foy):
 792  
 793      $string =~ s/ (
 794                   (^\w)    #at the beginning of the line
 795                     |      # or
 796                   (\s\w)   #preceded by whitespace
 797                     )
 798                  /\U$1/xg;
 799  
 800      $string =~ s/([\w']+)/\u\L$1/g;
 801  
 802  To make the whole line upper case:
 803  
 804      $line = uc($line);
 805  
 806  To force each word to be lower case, with the first letter upper case:
 807  
 808      $line =~ s/(\w+)/\u\L$1/g;
 809  
 810  You can (and probably should) enable locale awareness of those
 811  characters by placing a C<use locale> pragma in your program.
 812  See L<perllocale> for endless details on locales.
 813  
 814  This is sometimes referred to as putting something into "title
 815  case", but that's not quite accurate.  Consider the proper
 816  capitalization of the movie I<Dr. Strangelove or: How I Learned to
 817  Stop Worrying and Love the Bomb>, for example.
 818  
 819  Damian Conway's L<Text::Autoformat> module provides some smart
 820  case transformations:
 821  
 822      use Text::Autoformat;
 823      my $x = "Dr. Strangelove or: How I Learned to Stop ".
 824        "Worrying and Love the Bomb";
 825  
 826      print $x, "\n";
 827      for my $style (qw( sentence title highlight )) {
 828          print autoformat($x, { case => $style }), "\n";
 829          }
 830  
 831  =head2 How can I split a [character] delimited string except when inside [character]?
 832  
 833  Several modules can handle this sort of parsing--C<Text::Balanced>,
 834  C<Text::CSV>, C<Text::CSV_XS>, and C<Text::ParseWords>, among others.
 835  
 836  Take the example case of trying to split a string that is
 837  comma-separated into its different fields. You can't use C<split(/,/)>
 838  because you shouldn't split if the comma is inside quotes.  For
 839  example, take a data line like this:
 840  
 841      SAR001,"","Cimetrix, Inc","Bob Smith","CAM",N,8,1,0,7,"Error, Core Dumped"
 842  
 843  Due to the restriction of the quotes, this is a fairly complex
 844  problem.  Thankfully, we have Jeffrey Friedl, author of
 845  I<Mastering Regular Expressions>, to handle these for us.  He
 846  suggests (assuming your string is contained in C<$text>):
 847  
 848       @new = ();
 849       push(@new, $+) while $text =~ m{
 850           "([^\"\\]*(?:\\.[^\"\\]*)*)",?  # groups the phrase inside the quotes
 851          | ([^,]+),?
 852          | ,
 853          }gx;
 854       push(@new, undef) if substr($text,-1,1) eq ',';
 855  
 856  If you want to represent quotation marks inside a
 857  quotation-mark-delimited field, escape them with backslashes (eg,
 858  C<"like \"this\"">.
 859  
 860  Alternatively, the C<Text::ParseWords> module (part of the standard
 861  Perl distribution) lets you say:
 862  
 863      use Text::ParseWords;
 864      @new = quotewords(",", 0, $text);
 865  
 866  =head2 How do I strip blank space from the beginning/end of a string?
 867  
 868  (contributed by brian d foy)
 869  
 870  A substitution can do this for you. For a single line, you want to
 871  replace all the leading or trailing whitespace with nothing. You
 872  can do that with a pair of substitutions.
 873  
 874      s/^\s+//;
 875      s/\s+$//;
 876  
 877  You can also write that as a single substitution, although it turns
 878  out the combined statement is slower than the separate ones. That
 879  might not matter to you, though.
 880  
 881      s/^\s+|\s+$//g;
 882  
 883  In this regular expression, the alternation matches either at the
 884  beginning or the end of the string since the anchors have a lower
 885  precedence than the alternation. With the C</g> flag, the substitution
 886  makes all possible matches, so it gets both. Remember, the trailing
 887  newline matches the C<\s+>, and  the C<$> anchor can match to the
 888  physical end of the string, so the newline disappears too. Just add
 889  the newline to the output, which has the added benefit of preserving
 890  "blank" (consisting entirely of whitespace) lines which the C<^\s+>
 891  would remove all by itself.
 892  
 893      while( <> )
 894          {
 895          s/^\s+|\s+$//g;
 896          print "$_\n";
 897          }
 898  
 899  For a multi-line string, you can apply the regular expression
 900  to each logical line in the string by adding the C</m> flag (for
 901  "multi-line"). With the C</m> flag, the C<$> matches I<before> an
 902  embedded newline, so it doesn't remove it. It still removes the
 903  newline at the end of the string.
 904  
 905      $string =~ s/^\s+|\s+$//gm;
 906  
 907  Remember that lines consisting entirely of whitespace will disappear,
 908  since the first part of the alternation can match the entire string
 909  and replace it with nothing. If need to keep embedded blank lines,
 910  you have to do a little more work. Instead of matching any whitespace
 911  (since that includes a newline), just match the other whitespace.
 912  
 913      $string =~ s/^[\t\f ]+|[\t\f ]+$//mg;
 914  
 915  =head2 How do I pad a string with blanks or pad a number with zeroes?
 916  
 917  In the following examples, C<$pad_len> is the length to which you wish
 918  to pad the string, C<$text> or C<$num> contains the string to be padded,
 919  and C<$pad_char> contains the padding character. You can use a single
 920  character string constant instead of the C<$pad_char> variable if you
 921  know what it is in advance. And in the same way you can use an integer in
 922  place of C<$pad_len> if you know the pad length in advance.
 923  
 924  The simplest method uses the C<sprintf> function. It can pad on the left
 925  or right with blanks and on the left with zeroes and it will not
 926  truncate the result. The C<pack> function can only pad strings on the
 927  right with blanks and it will truncate the result to a maximum length of
 928  C<$pad_len>.
 929  
 930      # Left padding a string with blanks (no truncation):
 931      $padded = sprintf("%$pad_len}s", $text);
 932      $padded = sprintf("%*s", $pad_len, $text);  # same thing
 933  
 934      # Right padding a string with blanks (no truncation):
 935      $padded = sprintf("%-$pad_len}s", $text);
 936      $padded = sprintf("%-*s", $pad_len, $text); # same thing
 937  
 938      # Left padding a number with 0 (no truncation):
 939      $padded = sprintf("%0$pad_len}d", $num);
 940      $padded = sprintf("%0*d", $pad_len, $num); # same thing
 941  
 942      # Right padding a string with blanks using pack (will truncate):
 943      $padded = pack("A$pad_len",$text);
 944  
 945  If you need to pad with a character other than blank or zero you can use
 946  one of the following methods.  They all generate a pad string with the
 947  C<x> operator and combine that with C<$text>. These methods do
 948  not truncate C<$text>.
 949  
 950  Left and right padding with any character, creating a new string:
 951  
 952      $padded = $pad_char x ( $pad_len - length( $text ) ) . $text;
 953      $padded = $text . $pad_char x ( $pad_len - length( $text ) );
 954  
 955  Left and right padding with any character, modifying C<$text> directly:
 956  
 957      substr( $text, 0, 0 ) = $pad_char x ( $pad_len - length( $text ) );
 958      $text .= $pad_char x ( $pad_len - length( $text ) );
 959  
 960  =head2 How do I extract selected columns from a string?
 961  
 962  (contributed by brian d foy)
 963  
 964  If you know where the columns that contain the data, you can
 965  use C<substr> to extract a single column.
 966  
 967      my $column = substr( $line, $start_column, $length );
 968  
 969  You can use C<split> if the columns are separated by whitespace or
 970  some other delimiter, as long as whitespace or the delimiter cannot
 971  appear as part of the data.
 972  
 973      my $line    = ' fred barney   betty   ';
 974      my @columns = split /\s+/, $line;
 975          # ( '', 'fred', 'barney', 'betty' );
 976  
 977      my $line    = 'fred||barney||betty';
 978      my @columns = split /\|/, $line;
 979          # ( 'fred', '', 'barney', '', 'betty' );
 980  
 981  If you want to work with comma-separated values, don't do this since
 982  that format is a bit more complicated. Use one of the modules that
 983  handle that fornat, such as C<Text::CSV>, C<Text::CSV_XS>, or
 984  C<Text::CSV_PP>.
 985  
 986  If you want to break apart an entire line of fixed columns, you can use
 987  C<unpack> with the A (ASCII) format. by using a number after the format
 988  specifier, you can denote the column width. See the C<pack> and C<unpack>
 989  entries in L<perlfunc> for more details.
 990  
 991      my @fields = unpack( $line, "A8 A8 A8 A16 A4" );
 992  
 993  Note that spaces in the format argument to C<unpack> do not denote literal
 994  spaces. If you have space separated data, you may want C<split> instead.
 995  
 996  =head2 How do I find the soundex value of a string?
 997  
 998  (contributed by brian d foy)
 999  
1000  You can use the Text::Soundex module. If you want to do fuzzy or close
1001  matching, you might also try the C<String::Approx>, and
1002  C<Text::Metaphone>, and C<Text::DoubleMetaphone> modules.
1003  
1004  =head2 How can I expand variables in text strings?
1005  
1006  (contributed by brian d foy)
1007  
1008  If you can avoid it, don't, or if you can use a templating system,
1009  such as C<Text::Template> or C<Template> Toolkit, do that instead. You
1010  might even be able to get the job done with C<sprintf> or C<printf>:
1011  
1012      my $string = sprintf 'Say hello to %s and %s', $foo, $bar;
1013  
1014  However, for the one-off simple case where I don't want to pull out a
1015  full templating system, I'll use a string that has two Perl scalar
1016  variables in it. In this example, I want to expand C<$foo> and C<$bar>
1017  to their variable's values:
1018  
1019      my $foo = 'Fred';
1020      my $bar = 'Barney';
1021      $string = 'Say hello to $foo and $bar';
1022  
1023  One way I can do this involves the substitution operator and a double
1024  C</e> flag.  The first C</e> evaluates C<$1> on the replacement side and
1025  turns it into C<$foo>. The second /e starts with C<$foo> and replaces
1026  it with its value. C<$foo>, then, turns into 'Fred', and that's finally
1027  what's left in the string:
1028  
1029      $string =~ s/(\$\w+)/$1/eeg; # 'Say hello to Fred and Barney'
1030  
1031  The C</e> will also silently ignore violations of strict, replacing
1032  undefined variable names with the empty string. Since I'm using the
1033  C</e> flag (twice even!), I have all of the same security problems I 
1034  have with C<eval> in its string form. If there's something odd in
1035  C<$foo>, perhaps something like C<@{[ system "rm -rf /" ]}>, then
1036  I could get myself in trouble.
1037  
1038  To get around the security problem, I could also pull the values from
1039  a hash instead of evaluating variable names. Using a single C</e>, I
1040  can check the hash to ensure the value exists, and if it doesn't, I
1041  can replace the missing value with a marker, in this case C<???> to
1042  signal that I missed something:
1043  
1044      my $string = 'This has $foo and $bar';
1045      
1046      my %Replacements = (
1047          foo  => 'Fred',
1048          );
1049  
1050      # $string =~ s/\$(\w+)/$Replacements{$1}/g;
1051      $string =~ s/\$(\w+)/
1052          exists $Replacements{$1} ? $Replacements{$1} : '???'
1053          /eg;
1054  
1055      print $string;
1056  
1057  =head2 What's wrong with always quoting "$vars"?
1058  
1059  The problem is that those double-quotes force
1060  stringification--coercing numbers and references into strings--even
1061  when you don't want them to be strings.  Think of it this way:
1062  double-quote expansion is used to produce new strings.  If you already
1063  have a string, why do you need more?
1064  
1065  If you get used to writing odd things like these:
1066  
1067      print "$var";       # BAD
1068      $new = "$old";       # BAD
1069      somefunc("$var");    # BAD
1070  
1071  You'll be in trouble.  Those should (in 99.8% of the cases) be
1072  the simpler and more direct:
1073  
1074      print $var;
1075      $new = $old;
1076      somefunc($var);
1077  
1078  Otherwise, besides slowing you down, you're going to break code when
1079  the thing in the scalar is actually neither a string nor a number, but
1080  a reference:
1081  
1082      func(\@array);
1083      sub func {
1084          my $aref = shift;
1085          my $oref = "$aref";  # WRONG
1086          }
1087  
1088  You can also get into subtle problems on those few operations in Perl
1089  that actually do care about the difference between a string and a
1090  number, such as the magical C<++> autoincrement operator or the
1091  syscall() function.
1092  
1093  Stringification also destroys arrays.
1094  
1095      @lines = `command`;
1096      print "@lines";     # WRONG - extra blanks
1097      print @lines;       # right
1098  
1099  =head2 Why don't my E<lt>E<lt>HERE documents work?
1100  
1101  Check for these three things:
1102  
1103  =over 4
1104  
1105  =item There must be no space after the E<lt>E<lt> part.
1106  
1107  =item There (probably) should be a semicolon at the end.
1108  
1109  =item You can't (easily) have any space in front of the tag.
1110  
1111  =back
1112  
1113  If you want to indent the text in the here document, you
1114  can do this:
1115  
1116      # all in one
1117      ($VAR = <<HERE_TARGET) =~ s/^\s+//gm;
1118          your text
1119          goes here
1120      HERE_TARGET
1121  
1122  But the HERE_TARGET must still be flush against the margin.
1123  If you want that indented also, you'll have to quote
1124  in the indentation.
1125  
1126      ($quote = <<'    FINIS') =~ s/^\s+//gm;
1127              ...we will have peace, when you and all your works have
1128              perished--and the works of your dark master to whom you
1129              would deliver us. You are a liar, Saruman, and a corrupter
1130              of men's hearts.  --Theoden in /usr/src/perl/taint.c
1131          FINIS
1132      $quote =~ s/\s+--/\n--/;
1133  
1134  A nice general-purpose fixer-upper function for indented here documents
1135  follows.  It expects to be called with a here document as its argument.
1136  It looks to see whether each line begins with a common substring, and
1137  if so, strips that substring off.  Otherwise, it takes the amount of leading
1138  whitespace found on the first line and removes that much off each
1139  subsequent line.
1140  
1141      sub fix {
1142          local $_ = shift;
1143          my ($white, $leader);  # common whitespace and common leading string
1144          if (/^\s*(?:([^\w\s]+)(\s*).*\n)(?:\s*\1\2?.*\n)+$/) {
1145              ($white, $leader) = ($2, quotemeta($1));
1146          } else {
1147              ($white, $leader) = (/^(\s+)/, '');
1148          }
1149          s/^\s*?$leader(?:$white)?//gm;
1150          return $_;
1151      }
1152  
1153  This works with leading special strings, dynamically determined:
1154  
1155      $remember_the_main = fix<<'    MAIN_INTERPRETER_LOOP';
1156      @@@ int
1157      @@@ runops() {
1158      @@@     SAVEI32(runlevel);
1159      @@@     runlevel++;
1160      @@@     while ( op = (*op->op_ppaddr)() );
1161      @@@     TAINT_NOT;
1162      @@@     return 0;
1163      @@@ }
1164      MAIN_INTERPRETER_LOOP
1165  
1166  Or with a fixed amount of leading whitespace, with remaining
1167  indentation correctly preserved:
1168  
1169      $poem = fix<<EVER_ON_AND_ON;
1170         Now far ahead the Road has gone,
1171        And I must follow, if I can,
1172         Pursuing it with eager feet,
1173        Until it joins some larger way
1174         Where many paths and errands meet.
1175        And whither then? I cannot say.
1176          --Bilbo in /usr/src/perl/pp_ctl.c
1177      EVER_ON_AND_ON
1178  
1179  =head1 Data: Arrays
1180  
1181  =head2 What is the difference between a list and an array?
1182  
1183  An array has a changeable length.  A list does not.  An array is
1184  something you can push or pop, while a list is a set of values.  Some
1185  people make the distinction that a list is a value while an array is a
1186  variable. Subroutines are passed and return lists, you put things into
1187  list context, you initialize arrays with lists, and you C<foreach()>
1188  across a list.  C<@> variables are arrays, anonymous arrays are
1189  arrays, arrays in scalar context behave like the number of elements in
1190  them, subroutines access their arguments through the array C<@_>, and
1191  C<push>/C<pop>/C<shift> only work on arrays.
1192  
1193  As a side note, there's no such thing as a list in scalar context.
1194  When you say
1195  
1196      $scalar = (2, 5, 7, 9);
1197  
1198  you're using the comma operator in scalar context, so it uses the scalar
1199  comma operator.  There never was a list there at all! This causes the
1200  last value to be returned: 9.
1201  
1202  =head2 What is the difference between $array[1] and @array[1]?
1203  
1204  The former is a scalar value; the latter an array slice, making
1205  it a list with one (scalar) value.  You should use $ when you want a
1206  scalar value (most of the time) and @ when you want a list with one
1207  scalar value in it (very, very rarely; nearly never, in fact).
1208  
1209  Sometimes it doesn't make a difference, but sometimes it does.
1210  For example, compare:
1211  
1212      $good[0] = `some program that outputs several lines`;
1213  
1214  with
1215  
1216      @bad[0]  = `same program that outputs several lines`;
1217  
1218  The C<use warnings> pragma and the B<-w> flag will warn you about these
1219  matters.
1220  
1221  =head2 How can I remove duplicate elements from a list or array?
1222  
1223  (contributed by brian d foy)
1224  
1225  Use a hash. When you think the words "unique" or "duplicated", think
1226  "hash keys".
1227  
1228  If you don't care about the order of the elements, you could just
1229  create the hash then extract the keys. It's not important how you
1230  create that hash: just that you use C<keys> to get the unique
1231  elements.
1232  
1233      my %hash   = map { $_, 1 } @array;
1234      # or a hash slice: @hash{ @array } = ();
1235      # or a foreach: $hash{$_} = 1 foreach ( @array );
1236  
1237      my @unique = keys %hash;
1238  
1239  If you want to use a module, try the C<uniq> function from
1240  C<List::MoreUtils>. In list context it returns the unique elements,
1241  preserving their order in the list. In scalar context, it returns the
1242  number of unique elements.
1243  
1244      use List::MoreUtils qw(uniq);
1245  
1246      my @unique = uniq( 1, 2, 3, 4, 4, 5, 6, 5, 7 ); # 1,2,3,4,5,6,7
1247      my $unique = uniq( 1, 2, 3, 4, 4, 5, 6, 5, 7 ); # 7
1248  
1249  You can also go through each element and skip the ones you've seen
1250  before. Use a hash to keep track. The first time the loop sees an
1251  element, that element has no key in C<%Seen>. The C<next> statement
1252  creates the key and immediately uses its value, which is C<undef>, so
1253  the loop continues to the C<push> and increments the value for that
1254  key. The next time the loop sees that same element, its key exists in
1255  the hash I<and> the value for that key is true (since it's not 0 or
1256  C<undef>), so the next skips that iteration and the loop goes to the
1257  next element.
1258  
1259      my @unique = ();
1260      my %seen   = ();
1261  
1262      foreach my $elem ( @array )
1263          {
1264          next if $seen{ $elem }++;
1265          push @unique, $elem;
1266          }
1267  
1268  You can write this more briefly using a grep, which does the
1269  same thing.
1270  
1271      my %seen = ();
1272      my @unique = grep { ! $seen{ $_ }++ } @array;
1273  
1274  =head2 How can I tell whether a certain element is contained in a list or array?
1275  
1276  (portions of this answer contributed by Anno Siegel)
1277  
1278  Hearing the word "in" is an I<in>dication that you probably should have
1279  used a hash, not a list or array, to store your data.  Hashes are
1280  designed to answer this question quickly and efficiently.  Arrays aren't.
1281  
1282  That being said, there are several ways to approach this.  If you
1283  are going to make this query many times over arbitrary string values,
1284  the fastest way is probably to invert the original array and maintain a
1285  hash whose keys are the first array's values.
1286  
1287      @blues = qw/azure cerulean teal turquoise lapis-lazuli/;
1288      %is_blue = ();
1289      for (@blues) { $is_blue{$_} = 1 }
1290  
1291  Now you can check whether C<$is_blue{$some_color}>.  It might have
1292  been a good idea to keep the blues all in a hash in the first place.
1293  
1294  If the values are all small integers, you could use a simple indexed
1295  array.  This kind of an array will take up less space:
1296  
1297      @primes = (2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31);
1298      @is_tiny_prime = ();
1299      for (@primes) { $is_tiny_prime[$_] = 1 }
1300      # or simply  @istiny_prime[@primes] = (1) x @primes;
1301  
1302  Now you check whether $is_tiny_prime[$some_number].
1303  
1304  If the values in question are integers instead of strings, you can save
1305  quite a lot of space by using bit strings instead:
1306  
1307      @articles = ( 1..10, 150..2000, 2017 );
1308      undef $read;
1309      for (@articles) { vec($read,$_,1) = 1 }
1310  
1311  Now check whether C<vec($read,$n,1)> is true for some C<$n>.
1312  
1313  These methods guarantee fast individual tests but require a re-organization
1314  of the original list or array.  They only pay off if you have to test
1315  multiple values against the same array.
1316  
1317  If you are testing only once, the standard module C<List::Util> exports
1318  the function C<first> for this purpose.  It works by stopping once it
1319  finds the element. It's written in C for speed, and its Perl equivalent
1320  looks like this subroutine:
1321  
1322      sub first (&@) {
1323          my $code = shift;
1324          foreach (@_) {
1325              return $_ if &{$code}();
1326          }
1327          undef;
1328      }
1329  
1330  If speed is of little concern, the common idiom uses grep in scalar context
1331  (which returns the number of items that passed its condition) to traverse the
1332  entire list. This does have the benefit of telling you how many matches it
1333  found, though.
1334  
1335      my $is_there = grep $_ eq $whatever, @array;
1336  
1337  If you want to actually extract the matching elements, simply use grep in
1338  list context.
1339  
1340      my @matches = grep $_ eq $whatever, @array;
1341  
1342  =head2 How do I compute the difference of two arrays?  How do I compute the intersection of two arrays?
1343  
1344  Use a hash.  Here's code to do both and more.  It assumes that each
1345  element is unique in a given array:
1346  
1347      @union = @intersection = @difference = ();
1348      %count = ();
1349      foreach $element (@array1, @array2) { $count{$element}++ }
1350      foreach $element (keys %count) {
1351          push @union, $element;
1352          push @{ $count{$element} > 1 ? \@intersection : \@difference }, $element;
1353          }
1354  
1355  Note that this is the I<symmetric difference>, that is, all elements
1356  in either A or in B but not in both.  Think of it as an xor operation.
1357  
1358  =head2 How do I test whether two arrays or hashes are equal?
1359  
1360  The following code works for single-level arrays.  It uses a
1361  stringwise comparison, and does not distinguish defined versus
1362  undefined empty strings.  Modify if you have other needs.
1363  
1364      $are_equal = compare_arrays(\@frogs, \@toads);
1365  
1366      sub compare_arrays {
1367          my ($first, $second) = @_;
1368          no warnings;  # silence spurious -w undef complaints
1369          return 0 unless @$first == @$second;
1370          for (my $i = 0; $i < @$first; $i++) {
1371              return 0 if $first->[$i] ne $second->[$i];
1372              }
1373          return 1;
1374          }
1375  
1376  For multilevel structures, you may wish to use an approach more
1377  like this one.  It uses the CPAN module C<FreezeThaw>:
1378  
1379      use FreezeThaw qw(cmpStr);
1380      @a = @b = ( "this", "that", [ "more", "stuff" ] );
1381  
1382      printf "a and b contain %s arrays\n",
1383          cmpStr(\@a, \@b) == 0
1384          ? "the same"
1385          : "different";
1386  
1387  This approach also works for comparing hashes.  Here we'll demonstrate
1388  two different answers:
1389  
1390      use FreezeThaw qw(cmpStr cmpStrHard);
1391  
1392      %a = %b = ( "this" => "that", "extra" => [ "more", "stuff" ] );
1393      $a{EXTRA} = \%b;
1394      $b{EXTRA} = \%a;
1395  
1396      printf "a and b contain %s hashes\n",
1397      cmpStr(\%a, \%b) == 0 ? "the same" : "different";
1398  
1399      printf "a and b contain %s hashes\n",
1400      cmpStrHard(\%a, \%b) == 0 ? "the same" : "different";
1401  
1402  
1403  The first reports that both those the hashes contain the same data,
1404  while the second reports that they do not.  Which you prefer is left as
1405  an exercise to the reader.
1406  
1407  =head2 How do I find the first array element for which a condition is true?
1408  
1409  To find the first array element which satisfies a condition, you can
1410  use the C<first()> function in the C<List::Util> module, which comes
1411  with Perl 5.8. This example finds the first element that contains
1412  "Perl".
1413  
1414      use List::Util qw(first);
1415  
1416      my $element = first { /Perl/ } @array;
1417  
1418  If you cannot use C<List::Util>, you can make your own loop to do the
1419  same thing.  Once you find the element, you stop the loop with last.
1420  
1421      my $found;
1422      foreach ( @array ) {
1423          if( /Perl/ ) { $found = $_; last }
1424          }
1425  
1426  If you want the array index, you can iterate through the indices
1427  and check the array element at each index until you find one
1428  that satisfies the condition.
1429  
1430      my( $found, $index ) = ( undef, -1 );
1431      for( $i = 0; $i < @array; $i++ ) {
1432          if( $array[$i] =~ /Perl/ ) {
1433              $found = $array[$i];
1434              $index = $i;
1435              last;
1436              }
1437          }
1438  
1439  =head2 How do I handle linked lists?
1440  
1441  In general, you usually don't need a linked list in Perl, since with
1442  regular arrays, you can push and pop or shift and unshift at either
1443  end, or you can use splice to add and/or remove arbitrary number of
1444  elements at arbitrary points.  Both pop and shift are O(1)
1445  operations on Perl's dynamic arrays.  In the absence of shifts and
1446  pops, push in general needs to reallocate on the order every log(N)
1447  times, and unshift will need to copy pointers each time.
1448  
1449  If you really, really wanted, you could use structures as described in
1450  L<perldsc> or L<perltoot> and do just what the algorithm book tells
1451  you to do.  For example, imagine a list node like this:
1452  
1453      $node = {
1454          VALUE => 42,
1455          LINK  => undef,
1456          };
1457  
1458  You could walk the list this way:
1459  
1460      print "List: ";
1461      for ($node = $head;  $node; $node = $node->{LINK}) {
1462          print $node->{VALUE}, " ";
1463          }
1464      print "\n";
1465  
1466  You could add to the list this way:
1467  
1468      my ($head, $tail);
1469      $tail = append($head, 1);       # grow a new head
1470      for $value ( 2 .. 10 ) {
1471          $tail = append($tail, $value);
1472          }
1473  
1474      sub append {
1475          my($list, $value) = @_;
1476          my $node = { VALUE => $value };
1477          if ($list) {
1478              $node->{LINK} = $list->{LINK};
1479              $list->{LINK} = $node;
1480              }
1481          else {
1482              $_[0] = $node;      # replace caller's version
1483              }
1484          return $node;
1485          }
1486  
1487  But again, Perl's built-in are virtually always good enough.
1488  
1489  =head2 How do I handle circular lists?
1490  
1491  Circular lists could be handled in the traditional fashion with linked
1492  lists, or you could just do something like this with an array:
1493  
1494      unshift(@array, pop(@array));  # the last shall be first
1495      push(@array, shift(@array));   # and vice versa
1496  
1497  You can also use C<Tie::Cycle>:
1498  
1499      use Tie::Cycle;
1500  
1501      tie my $cycle, 'Tie::Cycle', [ qw( FFFFFF 000000 FFFF00 ) ];
1502  
1503      print $cycle; # FFFFFF
1504      print $cycle; # 000000
1505      print $cycle; # FFFF00
1506  
1507  =head2 How do I shuffle an array randomly?
1508  
1509  If you either have Perl 5.8.0 or later installed, or if you have
1510  Scalar-List-Utils 1.03 or later installed, you can say:
1511  
1512      use List::Util 'shuffle';
1513  
1514      @shuffled = shuffle(@list);
1515  
1516  If not, you can use a Fisher-Yates shuffle.
1517  
1518      sub fisher_yates_shuffle {
1519          my $deck = shift;  # $deck is a reference to an array
1520          my $i = @$deck;
1521          while (--$i) {
1522              my $j = int rand ($i+1);
1523              @$deck[$i,$j] = @$deck[$j,$i];
1524              }
1525      }
1526  
1527      # shuffle my mpeg collection
1528      #
1529      my @mpeg = <audio/*/*.mp3>;
1530      fisher_yates_shuffle( \@mpeg );    # randomize @mpeg in place
1531      print @mpeg;
1532  
1533  Note that the above implementation shuffles an array in place,
1534  unlike the C<List::Util::shuffle()> which takes a list and returns
1535  a new shuffled list.
1536  
1537  You've probably seen shuffling algorithms that work using splice,
1538  randomly picking another element to swap the current element with
1539  
1540      srand;
1541      @new = ();
1542      @old = 1 .. 10;  # just a demo
1543      while (@old) {
1544          push(@new, splice(@old, rand @old, 1));
1545          }
1546  
1547  This is bad because splice is already O(N), and since you do it N
1548  times, you just invented a quadratic algorithm; that is, O(N**2).
1549  This does not scale, although Perl is so efficient that you probably
1550  won't notice this until you have rather largish arrays.
1551  
1552  =head2 How do I process/modify each element of an array?
1553  
1554  Use C<for>/C<foreach>:
1555  
1556      for (@lines) {
1557          s/foo/bar/;    # change that word
1558          tr/XZ/ZX/;    # swap those letters
1559          }
1560  
1561  Here's another; let's compute spherical volumes:
1562  
1563      for (@volumes = @radii) {   # @volumes has changed parts
1564          $_ **= 3;
1565          $_ *= (4/3) * 3.14159;  # this will be constant folded
1566          }
1567  
1568  which can also be done with C<map()> which is made to transform
1569  one list into another:
1570  
1571      @volumes = map {$_ ** 3 * (4/3) * 3.14159} @radii;
1572  
1573  If you want to do the same thing to modify the values of the
1574  hash, you can use the C<values> function.  As of Perl 5.6
1575  the values are not copied, so if you modify $orbit (in this
1576  case), you modify the value.
1577  
1578      for $orbit ( values %orbits ) {
1579          ($orbit **= 3) *= (4/3) * 3.14159;
1580          }
1581  
1582  Prior to perl 5.6 C<values> returned copies of the values,
1583  so older perl code often contains constructions such as
1584  C<@orbits{keys %orbits}> instead of C<values %orbits> where
1585  the hash is to be modified.
1586  
1587  =head2 How do I select a random element from an array?
1588  
1589  Use the C<rand()> function (see L<perlfunc/rand>):
1590  
1591      $index   = rand @array;
1592      $element = $array[$index];
1593  
1594  Or, simply:
1595  
1596      my $element = $array[ rand @array ];
1597  
1598  =head2 How do I permute N elements of a list?
1599  X<List::Permuter> X<permute> X<Algorithm::Loops> X<Knuth>
1600  X<The Art of Computer Programming> X<Fischer-Krause>
1601  
1602  Use the C<List::Permutor> module on CPAN. If the list is actually an
1603  array, try the C<Algorithm::Permute> module (also on CPAN). It's
1604  written in XS code and is very efficient:
1605  
1606      use Algorithm::Permute;
1607  
1608      my @array = 'a'..'d';
1609      my $p_iterator = Algorithm::Permute->new ( \@array );
1610  
1611      while (my @perm = $p_iterator->next) {
1612         print "next permutation: (@perm)\n";
1613          }
1614  
1615  For even faster execution, you could do:
1616  
1617      use Algorithm::Permute;
1618  
1619      my @array = 'a'..'d';
1620  
1621      Algorithm::Permute::permute {
1622          print "next permutation: (@array)\n";
1623          } @array;
1624  
1625  Here's a little program that generates all permutations of all the
1626  words on each line of input. The algorithm embodied in the
1627  C<permute()> function is discussed in Volume 4 (still unpublished) of
1628  Knuth's I<The Art of Computer Programming> and will work on any list:
1629  
1630      #!/usr/bin/perl -n
1631      # Fischer-Krause ordered permutation generator
1632  
1633      sub permute (&@) {
1634          my $code = shift;
1635          my @idx = 0..$#_;
1636          while ( $code->(@_[@idx]) ) {
1637              my $p = $#idx;
1638              --$p while $idx[$p-1] > $idx[$p];
1639              my $q = $p or return;
1640              push @idx, reverse splice @idx, $p;
1641              ++$q while $idx[$p-1] > $idx[$q];
1642              @idx[$p-1,$q]=@idx[$q,$p-1];
1643          }
1644      }
1645  
1646      permute { print "@_\n" } split;
1647  
1648  The C<Algorithm::Loops> module also provides the C<NextPermute> and
1649  C<NextPermuteNum> functions which efficiently find all unique permutations
1650  of an array, even if it contains duplicate values, modifying it in-place:
1651  if its elements are in reverse-sorted order then the array is reversed,
1652  making it sorted, and it returns false; otherwise the next
1653  permutation is returned.
1654  
1655  C<NextPermute> uses string order and C<NextPermuteNum> numeric order, so
1656  you can enumerate all the permutations of C<0..9> like this:
1657  
1658      use Algorithm::Loops qw(NextPermuteNum);
1659      
1660      my @list= 0..9;
1661      do { print "@list\n" } while NextPermuteNum @list;
1662  
1663  =head2 How do I sort an array by (anything)?
1664  
1665  Supply a comparison function to sort() (described in L<perlfunc/sort>):
1666  
1667      @list = sort { $a <=> $b } @list;
1668  
1669  The default sort function is cmp, string comparison, which would
1670  sort C<(1, 2, 10)> into C<(1, 10, 2)>.  C<< <=> >>, used above, is
1671  the numerical comparison operator.
1672  
1673  If you have a complicated function needed to pull out the part you
1674  want to sort on, then don't do it inside the sort function.  Pull it
1675  out first, because the sort BLOCK can be called many times for the
1676  same element.  Here's an example of how to pull out the first word
1677  after the first number on each item, and then sort those words
1678  case-insensitively.
1679  
1680      @idx = ();
1681      for (@data) {
1682          ($item) = /\d+\s*(\S+)/;
1683          push @idx, uc($item);
1684          }
1685      @sorted = @data[ sort { $idx[$a] cmp $idx[$b] } 0 .. $#idx ];
1686  
1687  which could also be written this way, using a trick
1688  that's come to be known as the Schwartzian Transform:
1689  
1690      @sorted = map  { $_->[0] }
1691          sort { $a->[1] cmp $b->[1] }
1692          map  { [ $_, uc( (/\d+\s*(\S+)/)[0]) ] } @data;
1693  
1694  If you need to sort on several fields, the following paradigm is useful.
1695  
1696      @sorted = sort {
1697          field1($a) <=> field1($b) ||
1698          field2($a) cmp field2($b) ||
1699          field3($a) cmp field3($b)
1700          } @data;
1701  
1702  This can be conveniently combined with precalculation of keys as given
1703  above.
1704  
1705  See the F<sort> article in the "Far More Than You Ever Wanted
1706  To Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz for
1707  more about this approach.
1708  
1709  See also the question later in L<perlfaq4> on sorting hashes.
1710  
1711  =head2 How do I manipulate arrays of bits?
1712  
1713  Use C<pack()> and C<unpack()>, or else C<vec()> and the bitwise
1714  operations.
1715  
1716  For example, this sets C<$vec> to have bit N set if C<$ints[N]> was
1717  set:
1718  
1719      $vec = '';
1720      foreach(@ints) { vec($vec,$_,1) = 1 }
1721  
1722  Here's how, given a vector in C<$vec>, you can get those bits into your
1723  C<@ints> array:
1724  
1725      sub bitvec_to_list {
1726          my $vec = shift;
1727          my @ints;
1728          # Find null-byte density then select best algorithm
1729          if ($vec =~ tr/\0// / length $vec > 0.95) {
1730              use integer;
1731              my $i;
1732  
1733              # This method is faster with mostly null-bytes
1734              while($vec =~ /[^\0]/g ) {
1735                  $i = -9 + 8 * pos $vec;
1736                  push @ints, $i if vec($vec, ++$i, 1);
1737                  push @ints, $i if vec($vec, ++$i, 1);
1738                  push @ints, $i if vec($vec, ++$i, 1);
1739                  push @ints, $i if vec($vec, ++$i, 1);
1740                  push @ints, $i if vec($vec, ++$i, 1);
1741                  push @ints, $i if vec($vec, ++$i, 1);
1742                  push @ints, $i if vec($vec, ++$i, 1);
1743                  push @ints, $i if vec($vec, ++$i, 1);
1744                  }
1745              }
1746          else {
1747              # This method is a fast general algorithm
1748              use integer;
1749              my $bits = unpack "b*", $vec;
1750              push @ints, 0 if $bits =~ s/^(\d)// && $1;
1751              push @ints, pos $bits while($bits =~ /1/g);
1752              }
1753  
1754          return \@ints;
1755          }
1756  
1757  This method gets faster the more sparse the bit vector is.
1758  (Courtesy of Tim Bunce and Winfried Koenig.)
1759  
1760  You can make the while loop a lot shorter with this suggestion
1761  from Benjamin Goldberg:
1762  
1763      while($vec =~ /[^\0]+/g ) {
1764          push @ints, grep vec($vec, $_, 1), $-[0] * 8 .. $+[0] * 8;
1765          }
1766  
1767  Or use the CPAN module C<Bit::Vector>:
1768  
1769      $vector = Bit::Vector->new($num_of_bits);
1770      $vector->Index_List_Store(@ints);
1771      @ints = $vector->Index_List_Read();
1772  
1773  C<Bit::Vector> provides efficient methods for bit vector, sets of
1774  small integers and "big int" math.
1775  
1776  Here's a more extensive illustration using vec():
1777  
1778      # vec demo
1779      $vector = "\xff\x0f\xef\xfe";
1780      print "Ilya's string \\xff\\x0f\\xef\\xfe represents the number ",
1781      unpack("N", $vector), "\n";
1782      $is_set = vec($vector, 23, 1);
1783      print "Its 23rd bit is ", $is_set ? "set" : "clear", ".\n";
1784      pvec($vector);
1785  
1786      set_vec(1,1,1);
1787      set_vec(3,1,1);
1788      set_vec(23,1,1);
1789  
1790      set_vec(3,1,3);
1791      set_vec(3,2,3);
1792      set_vec(3,4,3);
1793      set_vec(3,4,7);
1794      set_vec(3,8,3);
1795      set_vec(3,8,7);
1796  
1797      set_vec(0,32,17);
1798      set_vec(1,32,17);
1799  
1800      sub set_vec {
1801          my ($offset, $width, $value) = @_;
1802          my $vector = '';
1803          vec($vector, $offset, $width) = $value;
1804          print "offset=$offset width=$width value=$value\n";
1805          pvec($vector);
1806          }
1807  
1808      sub pvec {
1809          my $vector = shift;
1810          my $bits = unpack("b*", $vector);
1811          my $i = 0;
1812          my $BASE = 8;
1813  
1814          print "vector length in bytes: ", length($vector), "\n";
1815          @bytes = unpack("A8" x length($vector), $bits);
1816          print "bits are: @bytes\n\n";
1817          }
1818  
1819  =head2 Why does defined() return true on empty arrays and hashes?
1820  
1821  The short story is that you should probably only use defined on scalars or
1822  functions, not on aggregates (arrays and hashes).  See L<perlfunc/defined>
1823  in the 5.004 release or later of Perl for more detail.
1824  
1825  =head1 Data: Hashes (Associative Arrays)
1826  
1827  =head2 How do I process an entire hash?
1828  
1829  (contributed by brian d foy)
1830  
1831  There are a couple of ways that you can process an entire hash. You
1832  can get a list of keys, then go through each key, or grab a one
1833  key-value pair at a time.
1834  
1835  To go through all of the keys, use the C<keys> function. This extracts
1836  all of the keys of the hash and gives them back to you as a list. You
1837  can then get the value through the particular key you're processing:
1838  
1839      foreach my $key ( keys %hash ) {
1840          my $value = $hash{$key}
1841          ...
1842          }
1843  
1844  Once you have the list of keys, you can process that list before you
1845  process the hashh elements. For instance, you can sort the keys so you
1846  can process them in lexical order:
1847  
1848      foreach my $key ( sort keys %hash ) {
1849          my $value = $hash{$key}
1850          ...
1851          }
1852  
1853  Or, you might want to only process some of the items. If you only want
1854  to deal with the keys that start with C<text:>, you can select just
1855  those using C<grep>:
1856  
1857      foreach my $key ( grep /^text:/, keys %hash ) {
1858          my $value = $hash{$key}
1859          ...
1860          }
1861  
1862  If the hash is very large, you might not want to create a long list of
1863  keys. To save some memory, you can grab on key-value pair at a time using
1864  C<each()>, which returns a pair you haven't seen yet:
1865  
1866      while( my( $key, $value ) = each( %hash ) ) {
1867          ...
1868          }
1869  
1870  The C<each> operator returns the pairs in apparently random order, so if
1871  ordering matters to you, you'll have to stick with the C<keys> method.
1872  
1873  The C<each()> operator can be a bit tricky though. You can't add or
1874  delete keys of the hash while you're using it without possibly
1875  skipping or re-processing some pairs after Perl internally rehashes
1876  all of the elements. Additionally, a hash has only one iterator, so if
1877  you use C<keys>, C<values>, or C<each> on the same hash, you can reset
1878  the iterator and mess up your processing. See the C<each> entry in
1879  L<perlfunc> for more details.
1880  
1881  =head2 What happens if I add or remove keys from a hash while iterating over it?
1882  
1883  (contributed by brian d foy)
1884  
1885  The easy answer is "Don't do that!"
1886  
1887  If you iterate through the hash with each(), you can delete the key
1888  most recently returned without worrying about it.  If you delete or add
1889  other keys, the iterator may skip or double up on them since perl
1890  may rearrange the hash table.  See the
1891  entry for C<each()> in L<perlfunc>.
1892  
1893  =head2 How do I look up a hash element by value?
1894  
1895  Create a reverse hash:
1896  
1897      %by_value = reverse %by_key;
1898      $key = $by_value{$value};
1899  
1900  That's not particularly efficient.  It would be more space-efficient
1901  to use:
1902  
1903      while (($key, $value) = each %by_key) {
1904          $by_value{$value} = $key;
1905          }
1906  
1907  If your hash could have repeated values, the methods above will only find
1908  one of the associated keys.   This may or may not worry you.  If it does
1909  worry you, you can always reverse the hash into a hash of arrays instead:
1910  
1911      while (($key, $value) = each %by_key) {
1912           push @{$key_list_by_value{$value}}, $key;
1913          }
1914  
1915  =head2 How can I know how many entries are in a hash?
1916  
1917  If you mean how many keys, then all you have to do is
1918  use the keys() function in a scalar context:
1919  
1920      $num_keys = keys %hash;
1921  
1922  The keys() function also resets the iterator, which means that you may
1923  see strange results if you use this between uses of other hash operators
1924  such as each().
1925  
1926  =head2 How do I sort a hash (optionally by value instead of key)?
1927  
1928  (contributed by brian d foy)
1929  
1930  To sort a hash, start with the keys. In this example, we give the list of
1931  keys to the sort function which then compares them ASCIIbetically (which
1932  might be affected by your locale settings). The output list has the keys
1933  in ASCIIbetical order. Once we have the keys, we can go through them to
1934  create a report which lists the keys in ASCIIbetical order.
1935  
1936      my @keys = sort { $a cmp $b } keys %hash;
1937  
1938      foreach my $key ( @keys )
1939          {
1940          printf "%-20s %6d\n", $key, $hash{$value};
1941          }
1942  
1943  We could get more fancy in the C<sort()> block though. Instead of
1944  comparing the keys, we can compute a value with them and use that
1945  value as the comparison.
1946  
1947  For instance, to make our report order case-insensitive, we use
1948  the C<\L> sequence in a double-quoted string to make everything
1949  lowercase. The C<sort()> block then compares the lowercased
1950  values to determine in which order to put the keys.
1951  
1952      my @keys = sort { "\L$a" cmp "\L$b" } keys %hash;
1953  
1954  Note: if the computation is expensive or the hash has many elements,
1955  you may want to look at the Schwartzian Transform to cache the
1956  computation results.
1957  
1958  If we want to sort by the hash value instead, we use the hash key
1959  to look it up. We still get out a list of keys, but this time they
1960  are ordered by their value.
1961  
1962      my @keys = sort { $hash{$a} <=> $hash{$b} } keys %hash;
1963  
1964  From there we can get more complex. If the hash values are the same,
1965  we can provide a secondary sort on the hash key.
1966  
1967      my @keys = sort {
1968          $hash{$a} <=> $hash{$b}
1969              or
1970          "\L$a" cmp "\L$b"
1971          } keys %hash;
1972  
1973  =head2 How can I always keep my hash sorted?
1974  X<hash tie sort DB_File Tie::IxHash>
1975  
1976  You can look into using the C<DB_File> module and C<tie()> using the
1977  C<$DB_BTREE> hash bindings as documented in L<DB_File/"In Memory
1978  Databases">. The C<Tie::IxHash> module from CPAN might also be
1979  instructive. Although this does keep your hash sorted, you might not
1980  like the slow down you suffer from the tie interface. Are you sure you
1981  need to do this? :)
1982  
1983  =head2 What's the difference between "delete" and "undef" with hashes?
1984  
1985  Hashes contain pairs of scalars: the first is the key, the
1986  second is the value.  The key will be coerced to a string,
1987  although the value can be any kind of scalar: string,
1988  number, or reference.  If a key C<$key> is present in
1989  %hash, C<exists($hash{$key})> will return true.  The value
1990  for a given key can be C<undef>, in which case
1991  C<$hash{$key}> will be C<undef> while C<exists $hash{$key}>
1992  will return true.  This corresponds to (C<$key>, C<undef>)
1993  being in the hash.
1994  
1995  Pictures help...  here's the C<%hash> table:
1996  
1997        keys  values
1998      +------+------+
1999      |  a   |  3   |
2000      |  x   |  7   |
2001      |  d   |  0   |
2002      |  e   |  2   |
2003      +------+------+
2004  
2005  And these conditions hold
2006  
2007      $hash{'a'}                       is true
2008      $hash{'d'}                       is false
2009      defined $hash{'d'}               is true
2010      defined $hash{'a'}               is true
2011      exists $hash{'a'}                is true (Perl 5 only)
2012      grep ($_ eq 'a', keys %hash)     is true
2013  
2014  If you now say
2015  
2016      undef $hash{'a'}
2017  
2018  your table now reads:
2019  
2020  
2021        keys  values
2022      +------+------+
2023      |  a   | undef|
2024      |  x   |  7   |
2025      |  d   |  0   |
2026      |  e   |  2   |
2027      +------+------+
2028  
2029  and these conditions now hold; changes in caps:
2030  
2031      $hash{'a'}                       is FALSE
2032      $hash{'d'}                       is false
2033      defined $hash{'d'}               is true
2034      defined $hash{'a'}               is FALSE
2035      exists $hash{'a'}                is true (Perl 5 only)
2036      grep ($_ eq 'a', keys %hash)     is true
2037  
2038  Notice the last two: you have an undef value, but a defined key!
2039  
2040  Now, consider this:
2041  
2042      delete $hash{'a'}
2043  
2044  your table now reads:
2045  
2046        keys  values
2047      +------+------+
2048      |  x   |  7   |
2049      |  d   |  0   |
2050      |  e   |  2   |
2051      +------+------+
2052  
2053  and these conditions now hold; changes in caps:
2054  
2055      $hash{'a'}                       is false
2056      $hash{'d'}                       is false
2057      defined $hash{'d'}               is true
2058      defined $hash{'a'}               is false
2059      exists $hash{'a'}                is FALSE (Perl 5 only)
2060      grep ($_ eq 'a', keys %hash)     is FALSE
2061  
2062  See, the whole entry is gone!
2063  
2064  =head2 Why don't my tied hashes make the defined/exists distinction?
2065  
2066  This depends on the tied hash's implementation of EXISTS().
2067  For example, there isn't the concept of undef with hashes
2068  that are tied to DBM* files. It also means that exists() and
2069  defined() do the same thing with a DBM* file, and what they
2070  end up doing is not what they do with ordinary hashes.
2071  
2072  =head2 How do I reset an each() operation part-way through?
2073  
2074  (contributed by brian d foy)
2075  
2076  You can use the C<keys> or C<values> functions to reset C<each>. To
2077  simply reset the iterator used by C<each> without doing anything else,
2078  use one of them in void context:
2079  
2080      keys %hash; # resets iterator, nothing else.
2081      values %hash; # resets iterator, nothing else.
2082  
2083  See the documentation for C<each> in L<perlfunc>.
2084  
2085  =head2 How can I get the unique keys from two hashes?
2086  
2087  First you extract the keys from the hashes into lists, then solve
2088  the "removing duplicates" problem described above.  For example:
2089  
2090      %seen = ();
2091      for $element (keys(%foo), keys(%bar)) {
2092          $seen{$element}++;
2093          }
2094      @uniq = keys %seen;
2095  
2096  Or more succinctly:
2097  
2098      @uniq = keys %{{%foo,%bar}};
2099  
2100  Or if you really want to save space:
2101  
2102      %seen = ();
2103      while (defined ($key = each %foo)) {
2104          $seen{$key}++;
2105      }
2106      while (defined ($key = each %bar)) {
2107          $seen{$key}++;
2108      }
2109      @uniq = keys %seen;
2110  
2111  =head2 How can I store a multidimensional array in a DBM file?
2112  
2113  Either stringify the structure yourself (no fun), or else
2114  get the MLDBM (which uses Data::Dumper) module from CPAN and layer
2115  it on top of either DB_File or GDBM_File.
2116  
2117  =head2 How can I make my hash remember the order I put elements into it?
2118  
2119  Use the C<Tie::IxHash> from CPAN.
2120  
2121      use Tie::IxHash;
2122  
2123      tie my %myhash, 'Tie::IxHash';
2124  
2125      for (my $i=0; $i<20; $i++) {
2126          $myhash{$i} = 2*$i;
2127          }
2128  
2129      my @keys = keys %myhash;
2130      # @keys = (0,1,2,3,...)
2131  
2132  =head2 Why does passing a subroutine an undefined element in a hash create it?
2133  
2134  If you say something like:
2135  
2136      somefunc($hash{"nonesuch key here"});
2137  
2138  Then that element "autovivifies"; that is, it springs into existence
2139  whether you store something there or not.  That's because functions
2140  get scalars passed in by reference.  If somefunc() modifies C<$_[0]>,
2141  it has to be ready to write it back into the caller's version.
2142  
2143  This has been fixed as of Perl5.004.
2144  
2145  Normally, merely accessing a key's value for a nonexistent key does
2146  I<not> cause that key to be forever there.  This is different than
2147  awk's behavior.
2148  
2149  =head2 How can I make the Perl equivalent of a C structure/C++ class/hash or array of hashes or arrays?
2150  
2151  Usually a hash ref, perhaps like this:
2152  
2153      $record = {
2154          NAME   => "Jason",
2155          EMPNO  => 132,
2156          TITLE  => "deputy peon",
2157          AGE    => 23,
2158          SALARY => 37_000,
2159          PALS   => [ "Norbert", "Rhys", "Phineas"],
2160      };
2161  
2162  References are documented in L<perlref> and the upcoming L<perlreftut>.
2163  Examples of complex data structures are given in L<perldsc> and
2164  L<perllol>.  Examples of structures and object-oriented classes are
2165  in L<perltoot>.
2166  
2167  =head2 How can I use a reference as a hash key?
2168  
2169  (contributed by brian d foy)
2170  
2171  Hash keys are strings, so you can't really use a reference as the key.
2172  When you try to do that, perl turns the reference into its stringified
2173  form (for instance, C<HASH(0xDEADBEEF)>). From there you can't get
2174  back the reference from the stringified form, at least without doing
2175  some extra work on your own. Also remember that hash keys must be
2176  unique, but two different variables can store the same reference (and
2177  those variables can change later).
2178  
2179  The C<Tie::RefHash> module, which is distributed with perl, might be
2180  what you want. It handles that extra work.
2181  
2182  =head1 Data: Misc
2183  
2184  =head2 How do I handle binary data correctly?
2185  
2186  Perl is binary clean, so it can handle binary data just fine.
2187  On Windows or DOS, however, you have to use C<binmode> for binary
2188  files to avoid conversions for line endings. In general, you should
2189  use C<binmode> any time you want to work with binary data.
2190  
2191  Also see L<perlfunc/"binmode"> or L<perlopentut>.
2192  
2193  If you're concerned about 8-bit textual data then see L<perllocale>.
2194  If you want to deal with multibyte characters, however, there are
2195  some gotchas.  See the section on Regular Expressions.
2196  
2197  =head2 How do I determine whether a scalar is a number/whole/integer/float?
2198  
2199  Assuming that you don't care about IEEE notations like "NaN" or
2200  "Infinity", you probably just want to use a regular expression.
2201  
2202      if (/\D/)            { print "has nondigits\n" }
2203      if (/^\d+$/)         { print "is a whole number\n" }
2204      if (/^-?\d+$/)       { print "is an integer\n" }
2205      if (/^[+-]?\d+$/)    { print "is a +/- integer\n" }
2206      if (/^-?\d+\.?\d*$/) { print "is a real number\n" }
2207      if (/^-?(?:\d+(?:\.\d*)?|\.\d+)$/) { print "is a decimal number\n" }
2208      if (/^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/)
2209              { print "a C float\n" }
2210  
2211  There are also some commonly used modules for the task.
2212  L<Scalar::Util> (distributed with 5.8) provides access to perl's
2213  internal function C<looks_like_number> for determining whether a
2214  variable looks like a number.  L<Data::Types> exports functions that
2215  validate data types using both the above and other regular
2216  expressions. Thirdly, there is C<Regexp::Common> which has regular
2217  expressions to match various types of numbers. Those three modules are
2218  available from the CPAN.
2219  
2220  If you're on a POSIX system, Perl supports the C<POSIX::strtod>
2221  function.  Its semantics are somewhat cumbersome, so here's a
2222  C<getnum> wrapper function for more convenient access.  This function
2223  takes a string and returns the number it found, or C<undef> for input
2224  that isn't a C float.  The C<is_numeric> function is a front end to
2225  C<getnum> if you just want to say, "Is this a float?"
2226  
2227      sub getnum {
2228          use POSIX qw(strtod);
2229          my $str = shift;
2230          $str =~ s/^\s+//;
2231          $str =~ s/\s+$//;
2232          $! = 0;
2233          my($num, $unparsed) = strtod($str);
2234          if (($str eq '') || ($unparsed != 0) || $!) {
2235                  return undef;
2236              }
2237          else {
2238              return $num;
2239              }
2240          }
2241  
2242      sub is_numeric { defined getnum($_[0]) }
2243  
2244  Or you could check out the L<String::Scanf> module on the CPAN
2245  instead. The C<POSIX> module (part of the standard Perl distribution)
2246  provides the C<strtod> and C<strtol> for converting strings to double
2247  and longs, respectively.
2248  
2249  =head2 How do I keep persistent data across program calls?
2250  
2251  For some specific applications, you can use one of the DBM modules.
2252  See L<AnyDBM_File>.  More generically, you should consult the C<FreezeThaw>
2253  or C<Storable> modules from CPAN.  Starting from Perl 5.8 C<Storable> is part
2254  of the standard distribution.  Here's one example using C<Storable>'s C<store>
2255  and C<retrieve> functions:
2256  
2257      use Storable;
2258      store(\%hash, "filename");
2259  
2260      # later on...
2261      $href = retrieve("filename");        # by ref
2262      %hash = %{ retrieve("filename") };   # direct to hash
2263  
2264  =head2 How do I print out or copy a recursive data structure?
2265  
2266  The C<Data::Dumper> module on CPAN (or the 5.005 release of Perl) is great
2267  for printing out data structures.  The C<Storable> module on CPAN (or the
2268  5.8 release of Perl), provides a function called C<dclone> that recursively
2269  copies its argument.
2270  
2271      use Storable qw(dclone);
2272      $r2 = dclone($r1);
2273  
2274  Where C<$r1> can be a reference to any kind of data structure you'd like.
2275  It will be deeply copied.  Because C<dclone> takes and returns references,
2276  you'd have to add extra punctuation if you had a hash of arrays that
2277  you wanted to copy.
2278  
2279      %newhash = %{ dclone(\%oldhash) };
2280  
2281  =head2 How do I define methods for every class/object?
2282  
2283  Use the C<UNIVERSAL> class (see L<UNIVERSAL>).
2284  
2285  =head2 How do I verify a credit card checksum?
2286  
2287  Get the C<Business::CreditCard> module from CPAN.
2288  
2289  =head2 How do I pack arrays of doubles or floats for XS code?
2290  
2291  The kgbpack.c code in the C<PGPLOT> module on CPAN does just this.
2292  If you're doing a lot of float or double processing, consider using
2293  the C<PDL> module from CPAN instead--it makes number-crunching easy.
2294  
2295  =head1 REVISION
2296  
2297  Revision: $Revision: 10394 $
2298  
2299  Date: $Date: 2007-12-09 18:47:15 +0100 (Sun, 09 Dec 2007) $
2300  
2301  See L<perlfaq> for source control details and availability.
2302  
2303  =head1 AUTHOR AND COPYRIGHT
2304  
2305  Copyright (c) 1997-2007 Tom Christiansen, Nathan Torkington, and
2306  other authors as noted. All rights reserved.
2307  
2308  This documentation is free; you can redistribute it and/or modify it
2309  under the same terms as Perl itself.
2310  
2311  Irrespective of its distribution, all code examples in this file
2312  are hereby placed into the public domain.  You are permitted and
2313  encouraged to use this code in your own programs for fun
2314  or for profit as you see fit.  A simple comment in the code giving
2315  credit would be courteous but is not required.


Generated: Tue Mar 17 22:47:18 2015 Cross-referenced by PHPXref 0.7.1