# Maintainer: Jschares <jacob.schares@gmail.com>                                                    
# Contributor: celmir <scibecelmir@tuxfamily.org>                                                   
pkgname=paintown                                                                                    
pkgver=3.3.1                                                                                        
pkgrel=1                                                                                            
pkgdesc="An open source fighting game in the same genre as Streets of Rage and Teenage Mutant Ninja Turtles."
arch=('i686' 'x86_64')                                                                              
url="http://paintown.sourceforge.net/"                                                              
license=('GPL')                                                                                     
depends=('python2' 'freetype2' 'allegro')                                                           
makedepends=('scons')                                                                               
install='paintown.install'                                                                          
source=(http://downloads.sourceforge.net/sourceforge/paintown/$pkgname-$pkgver.tar.gz               
        paintown.png                                                                                
	paintown.desktop)                                                                                  
md5sums=('61ae18b78ff4ca1caf287ddf7f8e0bf9'                                                         
         'ed547f1377212ea079cf9b0a1ad2d587'                                                         
         '4144c695ad0bc4621e96ef9760f33b19')                                                        
                                                                                                    
build() {                                                                                           
  cd "$srcdir/$pkgname-$pkgver"                                                                     
# fix python2 header                                                                                
  for file in $(find . -name '*.py' -print); do                                                     
     sed -i "s#/usr/bin/python#/usr/bin/env python2#" $file                                         
  done                                                                                              
  sed -i "s#python#python2#" Makefile                                                               
# fix path                                                                                          
  sed -i "s#hawknl/nl.h#nl.h#g" src/network/{network.h,network.cpp}                                 
  sed -i "s#dumb/include/##g" src/{main-menu.cpp,music.cpp,init.cpp}                                
  make || return 1                                                                                  
}                                                                                                   
                                                                                                    
package() {                                                                                         
  cd "$srcdir/$pkgname-$pkgver"                                                                     
  mkdir -p $pkgdir/usr/{bin,share/{paintown,pixmaps,applications,licenses/paintown}}                
  sed -i "s#\$dir/paintown-bin#\$install_bin/paintown-bin#" install.sh                              
  sh install.sh -d $pkgdir/usr/share/paintown -b $pkgdir/usr/bin                                    
  install -m644 $srcdir/paintown.desktop $pkgdir/usr/share/applications/paintown.desktop            
  install -m644 $srcdir/paintown.png $pkgdir/usr/share/pixmaps/paintown.png                         
  install -m644 LICENSE $pkgdir/usr/share/licenses/paintown/LICENSE                                 
  install -m644 LEGAL $pkgdir/usr/share/licenses/paintown/LEGAL                                     
}                                                                                                   
                                                                                                    
# vim:set ts=2 sw=2 et: